recipes-multimedia/musicpd/mpd_agldemo.inc

   1 FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
   2
   3 # Remove curl dependency to disable WebDAV support.
   4 # Ideally this should be addressed by adding a PACKAGECONFIG option
   5 # in the upstream recipe.
   6 DEPENDS:remove = "curl"
   7
   8 SRC_URI += "file://mpd-volatiles.conf"
   9
  10 # The older meson in poky dunfell complains about the use of the
  11 # build.{c_std,cpp_std} options even though they work, so we need to
  12 # flag them to be ignored in the unknown configure option QA test.
  13 # This can be removed after upgrading to Yocto Project 3.5.
  14 UNKNOWN_CONFIGURE_OPT_IGNORE = "build.c_std build.cpp_std"
  15
  16 # This also needs to be pushed upstream.
  17 PACKAGECONFIG[pipewire] = "-Dpipewire=enabled,-Dpipewire=disabled,pipewire"
  18
  19 # Prune the default configuration a bit to remove various streaming/server
  20 # options that are not required.
  21 PACKAGECONFIG = " \
  22     ${@bb.utils.contains("LICENSE_FLAGS_ACCEPTED", "commercial", "aac", "", d)} \
  23     bzip2 \
  24     daemon \
  25     ${@bb.utils.contains("LICENSE_FLAGS_ACCEPTED", "commercial", "ffmpeg aac", "", d)} \
  26     flac \
  27     libsamplerate \
  28     mpg123 \
  29     sndfile \
  30     opus \
  31     vorbis \
  32     wavpack \
  33     zlib \
  34     pipewire \
  35     id3tag \
  36 "
  37
  38 SYSTEMD_AUTO_ENABLE = "enable"
  39
  40 # Override default as AGL's PipeWire configuration does not make use of audio
  41 # group.  As opposed to using the group setting in mpd.conf, this keeps the
  42 # files created in /var/lib/mpd as mpd.mpd, which seems safer.
  43 USERADD_PARAM:${PN} = " \
  44     --system --no-create-home \
  45     --home ${localstatedir}/lib/mpd \
  46     --groups pipewire \
  47     --user-group mpd"
  48
  49 # Install volatile redirect for /var/lib/mpd to avoid any chance of metadata
  50 # corruption on reboot.  This matches what as previously done with the
  51 # lightmediascanner configuration.
  52 do_install:append() {
  53     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  54         install -D -m 0644 ${WORKDIR}/mpd-volatiles.conf ${D}${sysconfdir}/tmpfiles.d/mpd.conf
  55     fi
  56 }