recipes-multimedia/lightmediascanner/lightmediascanner_0.5.1.bb

   1 SUMMARY = "Lightweight media scanner"
   2 DESCRIPTION = "Lightweight media scanner meant to be used in not-so-powerful devices, like embedded systems or old machines."
   3 SECTION = "libs/multimedia"
   4
   5 LICENSE = "LGPLv2.1+"
   6 LIC_FILES_CHKSUM = "file://COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343 \
   7                     file://src/lib/lightmediascanner.c;endline=21;md5=6d8889bccb4c6c27e8b786342a3eb267"
   8
   9 DEPENDS = "file gawk glib-2.0 sqlite3"
  10
  11 PV = "0.5.1+git${SRCPV}"
  12 SRCREV = "adfddb3486276a5ed2f5008c9e43a811e1271cc9"
  13 SRC_URI = "git://github.com/profusion/lightmediascanner.git \
  14            file://id3-plugin-support-out-of-tree-build.patch \
  15            file://0001-Define-comparison_fn_t-for-non-glibc-systems.patch \
  16           "
  17
  18 S = "${WORKDIR}/git"
  19
  20 inherit autotools pkgconfig
  21
  22 EXTRA_OECONF = "--enable-static --disable-mp4"
  23
  24 PACKAGECONFIG ??= "ogg flac wave id3 m3u pls asf rm jpeg png"
  25 PACKAGECONFIG[generic] = "--enable-generic,--disable-generic,libav"
  26 PACKAGECONFIG[ogg] = "--enable-ogg,--disable-ogg,libogg libvorbis libtheora"
  27 PACKAGECONFIG[flac] = "--enable-flac,--disable-flac,flac"
  28 PACKAGECONFIG[wave] = "--enable-wave,--disable-wave"
  29 PACKAGECONFIG[id3] = "--enable-id3,--disable-id3"
  30 PACKAGECONFIG[m3u] = "--enable-m3u,--disable-m3u"
  31 PACKAGECONFIG[pls] = "--enable-pls,--disable-pls"
  32 PACKAGECONFIG[asf] = "--enable-asf,--disable-asf"
  33 PACKAGECONFIG[rm] = "--enable-rm,--disable-rm"
  34 PACKAGECONFIG[jpeg] = "--enable-jpeg,--disable-jpeg"
  35 PACKAGECONFIG[png] = "--enable-png,--disable-png"
  36
  37 do_install_append() {
  38        # Install "test" binary for corresponding package
  39        install -d ${D}/${bindir}
  40        install -m 755 ${B}/src/bin/.libs/test ${D}/${bindir}/test-lms
  41        # Remove .la files for loadable modules
  42        rm -f ${D}/${libdir}/${PN}/plugins/*.la
  43 }
  44
  45 FILES_${PN} += "${datadir}/dbus-1"
  46 FILES_${PN}-dbg += "${libdir}/${PN}/plugins/.debug"
  47
  48 PACKAGES_prepend = "${PN}-test "
  49 FILES_${PN}-test_prepend = "${bindir}/test-lms "
  50
  51 PACKAGES += "${PN}-meta"
  52 ALLOW_EMPTY_${PN}-meta = "1"
  53
  54 PACKAGES_DYNAMIC = "${PN}-plugin-*"
  55
  56 python populate_packages_prepend () {
  57     lms_libdir = d.expand('${libdir}/${PN}')
  58     pkgs = []
  59
  60     pkgs += do_split_packages(d, oe.path.join(lms_libdir, "plugins"), '^(.*)\.so$', d.expand('${PN}-plugin-%s'), 'LightMediaScanner plugin for %s', prepend=True, extra_depends=d.expand('${PN}'))
  61     metapkg = d.getVar('PN') + '-meta'
  62     d.setVar('RDEPENDS_' + metapkg, ' '.join(pkgs))
  63 }