recipes-multimedia/audiomanager-plugins/audiomanager-plugins_git.bb

   1 DESCRIPTION = "GENIVI Audio Manager Plugins"
   2 HOMEPAGE = "http://projects.genivi.org/audio-manager/home"
   3 LICENSE = "MPLv2"
   4 SECTION = "multimedia"
   5 DEPENDS = "audiomanager libxml2 dbus pulseaudio"
   6
   7 LIC_FILES_CHKSUM = "file://PluginControlInterfaceGeneric/LICENSE.txt;md5=815ca599c9df247a0c7f619bab123dad"
   8
   9 SRC_URI = " \
  10     git://github.com/tisogai/AudioManagerPlugins.git;protocol=https;branch=unknown_element_support \
  11   "
  12
  13 SRCREV = "bf5c5e8198b85e84363770150d5a02f553f43296"
  14
  15 S = "${WORKDIR}/git"
  16 inherit cmake
  17 OECMAKE_CXX_FLAGS += "-std=c++11"
  18 EXTRA_OECMAKE = " \
  19     -DWITH_COMMAND_INTERFACE_CAPI=OFF \
  20     -DWITH_COMMAND_INTERFACE_DBUS=ON \
  21     -DWITH_ROUTING_INTERFACE_ASYNC=OFF \
  22     -DWITH_ROUTING_INTERFACE_CAPI=OFF \
  23     -DWITH_ROUTING_INTERFACE_DBUS=ON \
  24     -DWITH_TEST_CONTROLLER=OFF \
  25     -DWITH_GENERIC_CONTROLLER=ON \
  26     -DCONTROLLER_CONFIG_DIR="/etc/audiomanager/control" \
  27 "
  28
  29 # NOTE: The specific product should have a separate customtypes.xsd
  30 # and should be appended to FILES_${PN} in product specific
  31 # audiomanager-generic-controller_git.bbappend
  32 FILES_${PN} = " \
  33     ${libdir}/audiomanager/control/libPluginControlInterfaceGeneric.so \
  34     ${sysconfdir}/audiomanager/control/audiomanagertypes.xsd \
  35     ${libdir}/audiomanager/command/libPluginCommandInterfaceDbus.so \
  36     ${libdir}/audiomanager/routing/libPluginRoutingInterfaceDbus.so \
  37     /usr/share/audiomanager/audiomanager/CommandInterface.xml \
  38     /usr/share/audiomanager/audiomanager/RoutingReceiver.xml \
  39 "
  40
  41 # NOTE: The specific product should have a separate customtypes.h
  42 # and should be appended to FILES_${PN}-dev in product specific
  43 # audiomanager-generic-controller_git.bbappend
  44 FILES_${PN}-dev = " \
  45     ${sysconfdir}/audiomanager/control/xsd2header.pl \
  46 "
  47
  48 FILES_${PN}-dbg += " \
  49     ${libdir}/audiomanager/control/.debug/libPluginControlInterfaceGeneric.so \
  50     ${libdir}/audiomanager/command/.debug/libPluginCommandInterfaceDbus.so \
  51     ${libdir}/audiomanager/routing/.debug/libPluginRoutingInterfaceDbus.so \
  52 "
  53
  54 # remove example configurations
  55 do_install_append() {
  56     rm -rf ${D}${sysconfdir}/audiomanager/control/*.xml
  57     rm -rf ${D}${sysconfdir}/audiomanager/control/customtypes.xsd
  58 }
  59
  60 RDEPENDS_${PN} = "virtual/audiomanager-plugins-config"