recipes-graphics/wayland/weston-ini-conf_agldemo.inc

   1 FILESEXTRAPATHS:prepend := "${THISDIR}/weston-ini-conf:"
   2
   3 SRC_URI += "file://weston.ini.kvm.in"
   4
   5 # as grpc-server is enabled in meta-agl-demo, we can enable it here
   6 SRC_URI += "file://grpc-server.cfg"
   7
   8 GUEST_VM1_IMAGE ?= "agl-ivi-demo-platform-flutter"
   9 GUEST_VM2_IMAGE ?= "agl-cluster-demo-platform-flutter"
  10
  11 do_compile:append() {
  12     # Put all of our cfg files together for a default portrait
  13     # orientation configuration
  14     rm -f ${WORKDIR}/weston.ini.flutter
  15     for F in ${WESTON_FRAGMENTS}; do
  16         cat ${WORKDIR}/${F}.cfg >> ${WORKDIR}/weston.ini.flutter
  17         if grep -q '\[output\]' ${WORKDIR}/${F}.cfg; then
  18             echo "activation-area=1080x1600+0,160" >> ${WORKDIR}/weston.ini.flutter
  19         fi
  20         echo >> ${WORKDIR}/weston.ini.flutter
  21     done
  22     sed -i -e '$ d' ${WORKDIR}/weston.ini.flutter
  23
  24     # Start with a canned configuration for a KVM host, filling in
  25     # the guest VM application ids to pin them to specific outputs.
  26     rm -f ${WORKDIR}/weston.ini.kvm
  27     sed -e "s/@GUEST_VM1_IMAGE@/${GUEST_VM1_IMAGE}/g" \
  28         -e "s/@GUEST_VM2_IMAGE@/${GUEST_VM2_IMAGE}/g" \
  29         ${WORKDIR}/weston.ini.kvm.in > ${WORKDIR}/weston.ini.kvm
  30 }
  31
  32 do_install:append() {
  33     install -m 0644 ${WORKDIR}/weston.ini.flutter ${D}${weston_ini_dir}/
  34     install -m 0644 ${WORKDIR}/weston.ini.kvm ${D}${weston_ini_dir}/
  35 }
  36
  37 PACKAGE_BEFORE_PN += "${PN}-flutter ${PN}-kvm"
  38
  39 FILES:${PN}-flutter = "${weston_ini_dir}/weston.ini.flutter"
  40
  41 RPROVIDES:${PN}-flutter = "weston-ini"
  42 RCONFLICTS:${PN}-flutter = "${PN}"
  43 ALTERNATIVE:${PN}-flutter = "weston.ini"
  44 ALTERNATIVE_TARGET_${PN}-flutter = "${weston_ini_dir}/weston.ini.flutter"
  45
  46 FILES:${PN}-kvm = "${weston_ini_dir}/weston.ini.kvm"
  47
  48 RPROVIDES:${PN}-kvm = "weston-ini"
  49 RCONFLICTS:${PN}-kvm = "${PN}"
  50 ALTERNATIVE:${PN}-kvm = "weston.ini"
  51 ALTERNATIVE_TARGET_${PN}-kvm = "${weston_ini_dir}/weston.ini.kvm"