recipes-demo/navigation/tbtnavi_git.bb

   1 SUMMARY     = "AGL Reference Navigation Cluster Streaming application"
   2 DESCRIPTION = "Demo AGL turn by turn cluster navigation application based on QtLocation widget."
   3 HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/admin/repos/apps/tbtnavi"
   4 SECTION     = "apps"
   5
   6 LICENSE = "Apache-2.0 & ISC & BSD-3-Clause & BSL-1.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984 \
   8                     file://LICENSE.mapbox-cheap-ruler-cpp;md5=761263ee6bdc98e8697d9fbc897021ba \
   9                     file://LICENSE.mapbox-geometry.hpp;md5=6e44f5d6aeec54f40fc84eebe3c6fc6c \
  10                     file://LICENSE.mapbox-variant;md5=79558839a9db3e807e4ae6f8cd100c1c \
  11                     file://include/mapbox/recursive_wrapper.hpp;beginline=4;endline=13;md5=cd3341aae76c0cf8345935abd20f0051 \
  12 "
  13
  14 DEPENDS = " \
  15     qtbase \
  16     qtquickcontrols2 \
  17     qtlocation \
  18     libqtappfw \
  19     wayland-native \
  20     qtwayland-native \
  21 "
  22
  23 PV = "2.0+git${SRCPV}"
  24
  25 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/tbtnavi;protocol=https;branch=${AGL_BRANCH} \
  26            file://tbtnavi.service \
  27            file://tbtnavi.conf \
  28            file://tbtnavi.token \
  29 "
  30 SRCREV = "81ded150718320da690908544f041addb2f56102"
  31
  32 S = "${WORKDIR}/git"
  33
  34 inherit qmake5 systemd pkgconfig
  35
  36 do_install:append() {
  37     install -d ${D}${systemd_user_unitdir}/agl-session.target.wants
  38     install -m0644 ${WORKDIR}/tbtnavi.service ${D}${systemd_user_unitdir}/tbtnavi.service
  39     ln -s ../tbtnavi.service ${D}${systemd_user_unitdir}/agl-session.target.wants/tbtnavi.service
  40
  41     # Currently using default global client and CA certificates
  42     # for KUKSA.val SSL, installing app specific ones would go here.
  43
  44     # VIS authorization token file for KUKSA.val should ideally not
  45     # be readable by other users, but currently that's not doable
  46     # until a packaging/sandboxing/MAC scheme is (re)implemented or
  47     # something like OAuth is plumbed in as an alternative.
  48     install -d ${D}${sysconfdir}/xdg/AGL/tbtnavi
  49     install -m 0644 ${WORKDIR}/tbtnavi.conf ${D}${sysconfdir}/xdg/AGL/
  50     install -m 0644 ${WORKDIR}/tbtnavi.token ${D}${sysconfdir}/xdg/AGL/tbtnavi/
  51 }
  52
  53 FILES:${PN} += " ${systemd_user_unitdir}"
  54
  55 RDEPENDS:${PN} += " \
  56     qtlocation \
  57     ondemandnavi-config \
  58     libqtappfw \
  59 "