recipes-demo/navigation/tbtnavi_git.bb

   1 SUMMARY     = "AGL Reference Navigation Cluster Streaming application"
   2 DESCRIPTION = "Demo AGL turn by turn cluster navigation application based on QtLocation widget."
   3 HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/admin/repos/apps/tbtnavi"
   4 SECTION     = "apps"
   5
   6 LICENSE = "Apache-2.0 & ISC & BSD-3-Clause & BSL-1.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984 \
   8                     file://LICENSE.mapbox-cheap-ruler-cpp;md5=761263ee6bdc98e8697d9fbc897021ba \
   9                     file://LICENSE.mapbox-geometry.hpp;md5=6e44f5d6aeec54f40fc84eebe3c6fc6c \
  10                     file://LICENSE.mapbox-variant;md5=79558839a9db3e807e4ae6f8cd100c1c \
  11                     file://include/mapbox/recursive_wrapper.hpp;beginline=4;endline=13;md5=cd3341aae76c0cf8345935abd20f0051 \
  12 "
  13
  14 DEPENDS = " \
  15     qtbase \
  16     qtquickcontrols2 \
  17     qtlocation \
  18     libqtappfw \
  19     qtwayland-native \
  20     protobuf \
  21     grpc \
  22     grpc-native \
  23 "
  24
  25 PV = "2.0+git${SRCPV}"
  26
  27 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/tbtnavi;protocol=https;branch=${AGL_BRANCH} \
  28            file://tbtnavi.service \
  29            file://tbtnavi.conf \
  30            file://tbtnavi.conf.kvm-demo \
  31            file://tbtnavi.token \
  32            file://kvm.conf \
  33 "
  34 SRCREV = "f00c1e19f5c4cbcd185c8043f3062612bf1537f7"
  35
  36 S = "${WORKDIR}/git"
  37
  38 inherit meson systemd pkgconfig update-alternatives
  39
  40 SYSTEMD_SERVICE:${PN} = "${BPN}.service"
  41
  42 do_install:append() {
  43     install -D -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
  44
  45     install -D -m 0644 ${WORKDIR}/kvm.conf ${D}${systemd_system_unitdir}/${BPN}.service.d/kvm.conf
  46
  47     # Currently using default global client and CA certificates
  48     # for KUKSA.val SSL, installing app specific ones would go here.
  49
  50     # VIS authorization token file for KUKSA.val should ideally not
  51     # be readable by other users, but currently that's not doable
  52     # until a packaging/sandboxing/MAC scheme is (re)implemented or
  53     # something like OAuth is plumbed in as an alternative.
  54     install -d ${D}${sysconfdir}/xdg/AGL/tbtnavi
  55     install -m 0644 ${WORKDIR}/tbtnavi.conf ${D}${sysconfdir}/xdg/AGL/tbtnavi.conf.default
  56     install -m 0644 ${WORKDIR}/tbtnavi.conf.kvm-demo ${D}${sysconfdir}/xdg/AGL/
  57     install -m 0644 ${WORKDIR}/tbtnavi.token ${D}${sysconfdir}/xdg/AGL/tbtnavi/
  58 }
  59
  60 ALTERNATIVE_LINK_NAME[tbtnavi.conf] = "${sysconfdir}/xdg/AGL/tbtnavi.conf"
  61
  62 RDEPENDS:${PN} += " \
  63     qtwayland \
  64     qtbase-qmlplugins \
  65     qtgraphicaleffects-qmlplugins \
  66     qtlocation \
  67     ondemandnavi-config \
  68     libqtappfw \
  69 "
  70
  71 PACKAGE_BEFORE_PN += "${PN}-conf ${PN}-conf-kvm-demo"
  72
  73 FILES:${PN}-conf += "${sysconfdir}/xdg/AGL/tbtnavi.conf.default"
  74 RDEPENDS:${PN}-conf = "${PN}"
  75 RPROVIDES:${PN}-conf = "tbtnavi.conf"
  76 RCONFLICTS:${PN}-conf = "${PN}-conf-kvm-demo"
  77 ALTERNATIVE:${PN}-conf = "tbtnavi.conf"
  78 ALTERNATIVE_TARGET_${PN}-conf = "${sysconfdir}/xdg/AGL/tbtnavi.conf.default"
  79
  80 FILES:${PN}-conf-kvm-demo += " \
  81     ${sysconfdir}/xdg/AGL/tbtnavi.conf.kvm-demo \
  82     ${systemd_system_unitdir}/tbtnavi.service.d/kvm.conf \
  83 "
  84 RDEPENDS:${PN}-conf-kvm-demo = "${PN}"
  85 RPROVIDES:${PN}-conf-kvm-demo = "tbtnavi.conf"
  86 RCONFLICTS:${PN}-conf-kvm-demo = "${PN}-conf"
  87 ALTERNATIVE:${PN}-conf-kvm-demo = "tbtnavi.conf"
  88 ALTERNATIVE_TARGET_${PN}-conf-kvm-demo = "${sysconfdir}/xdg/AGL/tbtnavi.conf.kvm-demo"