recipes-demo/navigation/tbtnavi_git.bb

   1 SUMMARY     = "AGL Reference Navigation Cluster Streaming application"
   2 DESCRIPTION = "Demo AGL turn by turn cluster navigation application based on QtLocation widget."
   3 HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/admin/repos/apps/tbtnavi"
   4 SECTION     = "apps"
   5
   6 LICENSE = "Apache-2.0 & ISC & BSD-3-Clause & BSL-1.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984 \
   8                     file://LICENSE.mapbox-cheap-ruler-cpp;md5=761263ee6bdc98e8697d9fbc897021ba \
   9                     file://LICENSE.mapbox-geometry.hpp;md5=6e44f5d6aeec54f40fc84eebe3c6fc6c \
  10                     file://LICENSE.mapbox-variant;md5=79558839a9db3e807e4ae6f8cd100c1c \
  11                     file://include/mapbox/recursive_wrapper.hpp;beginline=4;endline=13;md5=cd3341aae76c0cf8345935abd20f0051 \
  12 "
  13
  14 DEPENDS = " \
  15     qtbase \
  16     qtquickcontrols2 \
  17     qtlocation \
  18     libqtappfw \
  19     qtwayland-native \
  20     protobuf \
  21     grpc \
  22     grpc-native \
  23 "
  24
  25 PV = "2.0+git${SRCPV}"
  26
  27 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/tbtnavi;protocol=https;branch=${AGL_BRANCH} \
  28            file://tbtnavi.service \
  29            file://tbtnavi.conf \
  30            file://tbtnavi.token \
  31 "
  32 SRCREV = "f00c1e19f5c4cbcd185c8043f3062612bf1537f7"
  33
  34 S = "${WORKDIR}/git"
  35
  36 inherit meson systemd pkgconfig
  37
  38 SYSTEMD_SERVICE:${PN} = "${BPN}.service"
  39
  40 do_install:append() {
  41     install -D -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
  42
  43     # Currently using default global client and CA certificates
  44     # for KUKSA.val SSL, installing app specific ones would go here.
  45
  46     # VIS authorization token file for KUKSA.val should ideally not
  47     # be readable by other users, but currently that's not doable
  48     # until a packaging/sandboxing/MAC scheme is (re)implemented or
  49     # something like OAuth is plumbed in as an alternative.
  50     install -d ${D}${sysconfdir}/xdg/AGL/tbtnavi
  51     install -m 0644 ${WORKDIR}/tbtnavi.conf ${D}${sysconfdir}/xdg/AGL/
  52     install -m 0644 ${WORKDIR}/tbtnavi.token ${D}${sysconfdir}/xdg/AGL/tbtnavi/
  53 }
  54
  55 RDEPENDS:${PN} += " \
  56     qtlocation \
  57     ondemandnavi-config \
  58     libqtappfw \
  59 "