recipes-demo/navigation/ondemandnavi_git.bb

   1 SUMMARY     = "Navigation application."
   2 DESCRIPTION = "AGL demonstration Navigation application based on QtLocation widget."
   3 HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/ondemandnavi"
   4 SECTION     = "apps"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
   8
   9 DEPENDS = "qtquickcontrols2 qtlocation libqtappfw"
  10
  11 PV = "2.0+git${SRCPV}"
  12
  13 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/ondemandnavi;protocol=https;branch=${AGL_BRANCH} \
  14            file://navigation.conf \
  15            file://navigation.conf.kvm-demo \
  16            file://navigation.token \
  17 "
  18 SRCREV = "d6b883ef6bdb63fb501b03d64c9a32bc29b7b2c7"
  19
  20 S = "${WORKDIR}/git"
  21
  22 inherit qmake5 pkgconfig agl-app update-alternatives
  23
  24 AGL_APP_ID = "navigation"
  25 AGL_APP_NAME = "Navigation"
  26
  27 do_install:append() {
  28     # Currently using default global client and CA certificates
  29     # for KUKSA.val SSL, installing app specific ones would go here.
  30
  31     # VIS authorization token file for KUKSA.val should ideally not
  32     # be readable by other users, but currently that's not doable
  33     # until a packaging/sandboxing/MAC scheme is (re)implemented or
  34     # something like OAuth is plumbed in as an alternative.
  35     install -d ${D}${sysconfdir}/xdg/AGL/navigation
  36     install -m 0644 ${WORKDIR}/navigation.conf ${D}${sysconfdir}/xdg/AGL/navigation.conf.default
  37     install -m 0644 ${WORKDIR}/navigation.conf.kvm-demo ${D}${sysconfdir}/xdg/AGL/
  38     install -m 0644 ${WORKDIR}/navigation.token ${D}${sysconfdir}/xdg/AGL/navigation/
  39 }
  40
  41 ALTERNATIVE_LINK_NAME[navigation.conf] = "${sysconfdir}/xdg/AGL/navigation.conf"
  42
  43 PACKAGE_BEFORE_PN += "${PN}-conf ${PN}-conf-kvm-demo"
  44
  45 FILES:${PN}-conf += "${sysconfdir}/xdg/AGL/navigation.conf.default"
  46 RDEPENDS:${PN}-conf = "${PN}"
  47 RPROVIDES:${PN}-conf = "navigation.conf"
  48 RCONFLICTS:${PN}-conf = "${PN}-conf-kvm-demo"
  49 ALTERNATIVE:${PN}-conf = "navigation.conf"
  50 ALTERNATIVE_TARGET_${PN}-conf = "${sysconfdir}/xdg/AGL/navigation.conf.default"
  51
  52 FILES:${PN}-conf-kvm-demo += "${sysconfdir}/xdg/AGL/navigation.conf.kvm-demo"
  53 RDEPENDS:${PN}-conf-kvm-demo = "${PN}"
  54 RPROVIDES:${PN}-conf-kvm-demo = "navigation.conf"
  55 RCONFLICTS:${PN}-conf-kvm-demo = "${PN}-conf"
  56 ALTERNATIVE:${PN}-conf-kvm-demo = "navigation.conf"
  57 ALTERNATIVE_TARGET_${PN}-conf-kvm-demo = "${sysconfdir}/xdg/AGL/navigation.conf.kvm-demo"
  58
  59 RDEPENDS:${PN} += " \
  60     qtwayland \
  61     qtbase-qmlplugins \
  62     qtgraphicaleffects-qmlplugins \
  63     qtquickcontrols-qmlplugins \
  64     qtquickcontrols2-qmlplugins \
  65     qtquickcontrols2-agl \
  66     qtquickcontrols2-agl-style \
  67     qtlocation \
  68     flite \
  69     libqtappfw \
  70     openjtalk \
  71     gstreamer1.0 \
  72     ondemandnavi-config \
  73 "