recipes-demo/homescreen/homescreen_git.bb

   1 SUMMARY     = "Home Screen application"
   2 DESCRIPTION = "AGL demonstration Home Screen application"
   3 HOMEPAGE    = "http://docs.automotivelinux.org"
   4 LICENSE     = "Apache-2.0"
   5 SECTION     = "apps"
   6 LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
   7
   8 DEPENDS = " \
   9     qtbase \
  10     qtdeclarative \
  11     qtquickcontrols2 \
  12     libqtappfw \
  13     wayland-native \
  14     wayland \
  15     qtwayland \
  16     qtwayland-native \
  17     agl-compositor \
  18     applaunchd \
  19 "
  20
  21 PV = "1.0+git${SRCPV}"
  22
  23 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/homescreen;protocol=https;branch=${AGL_BRANCH} \
  24            file://homescreen.service \
  25            file://homescreen.conf \
  26            file://homescreen.token \
  27 "
  28 SRCREV = "2de7cadddde53bc87328df3b1cabeff4a00932ba"
  29
  30 S = "${WORKDIR}/git"
  31
  32 inherit meson pkgconfig systemd
  33
  34 PATH:prepend = "${STAGING_DIR_NATIVE}${OE_QMAKE_PATH_QT_BINS}:"
  35
  36 OE_QMAKE_CXXFLAGS:append = " ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', '' , '-DQT_NO_DEBUG_OUTPUT', d)}"
  37
  38 SYSTEMD_SERVICE:${PN} = "${BPN}.service"
  39
  40 do_install:append() {
  41     install -D -m0644 ${WORKDIR}/homescreen.service ${D}${systemd_system_unitdir}/homescreen.service
  42
  43     # Currently using default global client and CA certificates
  44     # for KUKSA.val SSL, installing app specific ones would go here.
  45
  46     # VIS authorization token file for KUKSA.val should ideally not
  47     # be readable by other users, but currently that's not doable
  48     # until a packaging/sandboxing/MAC scheme is (re)implemented or
  49     # something like OAuth is plumbed in as an alternative.
  50     install -d ${D}${sysconfdir}/xdg/AGL/homescreen
  51     install -m 0644 ${WORKDIR}/homescreen.conf ${D}${sysconfdir}/xdg/AGL/
  52     install -m 0644 ${WORKDIR}/homescreen.token ${D}${sysconfdir}/xdg/AGL/homescreen/
  53 }
  54
  55 RDEPENDS:${PN} += " \
  56     libqtappfw \
  57     applaunchd \
  58     qtwayland \
  59     qtbase-qmlplugins \
  60     qtgraphicaleffects-qmlplugins \
  61 "