recipes-demo/homescreen/homescreen_git.bb

   1 SUMMARY     = "Home Screen application"
   2 DESCRIPTION = "AGL demonstration Home Screen application"
   3 HOMEPAGE    = "http://docs.automotivelinux.org"
   4 LICENSE     = "Apache-2.0"
   5 SECTION     = "apps"
   6 LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
   7
   8 DEPENDS = " \
   9     qtbase \
  10     qtdeclarative \
  11     qtquickcontrols2 \
  12     libqtappfw \
  13     wayland-native \
  14     wayland \
  15     qtwayland \
  16     qtwayland-native \
  17     protobuf \
  18     grpc grpc-native \
  19     agl-compositor \
  20     applaunchd \
  21 "
  22
  23 PV = "1.0+git${SRCPV}"
  24
  25 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/homescreen;protocol=https;branch=${AGL_BRANCH} \
  26            file://homescreen.service \
  27            file://homescreen.conf \
  28            file://homescreen.token \
  29 "
  30 SRCREV = "18b0219570009e67ed0df596f5fa145dd29eed6e"
  31
  32 S = "${WORKDIR}/git"
  33
  34 inherit meson pkgconfig systemd
  35
  36 PATH:prepend = "${STAGING_DIR_NATIVE}${OE_QMAKE_PATH_QT_BINS}:"
  37
  38 OE_QMAKE_CXXFLAGS:append = " ${@bb.utils.contains('DISTRO_FEATURES', 'agl-devel', '' , '-DQT_NO_DEBUG_OUTPUT', d)}"
  39
  40 SYSTEMD_SERVICE:${PN} = "${BPN}.service"
  41
  42 do_install:append() {
  43     install -D -m0644 ${WORKDIR}/homescreen.service ${D}${systemd_system_unitdir}/homescreen.service
  44
  45     # Currently using default global client and CA certificates
  46     # for KUKSA.val SSL, installing app specific ones would go here.
  47
  48     # VIS authorization token file for KUKSA.val should ideally not
  49     # be readable by other users, but currently that's not doable
  50     # until a packaging/sandboxing/MAC scheme is (re)implemented or
  51     # something like OAuth is plumbed in as an alternative.
  52     install -d ${D}${sysconfdir}/xdg/AGL/homescreen
  53     install -m 0644 ${WORKDIR}/homescreen.conf ${D}${sysconfdir}/xdg/AGL/
  54     install -m 0644 ${WORKDIR}/homescreen.token ${D}${sysconfdir}/xdg/AGL/homescreen/
  55 }
  56
  57 RDEPENDS:${PN} += " \
  58     libqtappfw \
  59     applaunchd \
  60     qtwayland \
  61     qtbase-qmlplugins \
  62     qtgraphicaleffects-qmlplugins \
  63 "