recipes-demo/flutter-ics-homescreen/flutter-ics-homescreen_git.bb

   1 SUMMARY = "AGL ICS Flutter Homescreen"
   2 DESCRIPTION = "Demo Flutter homescreen for Automotive Grade Linux by ICS."
   3 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/apps/flutter-ics-homescreen"
   4 SECTION = "graphics"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
   8
   9 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/flutter-ics-homescreen;protocol=https;branch=${AGL_BRANCH} \
  10   file://change_grpc_port.patch \
  11   file://flutter-ics-homescreen.json \
  12   file://flutter-ics-homescreen.service \
  13   file://ics-homescreen.yaml \
  14   file://ics-homescreen.token \
  15 "
  16 SRCREV = "70ec8a79a121471a004e7e4c23157d10157e136f"
  17
  18 S = "${WORKDIR}/git"
  19
  20 PUBSPEC_APPNAME = "flutter_ics_homescreen"
  21 FLUTTER_APPLICATION_INSTALL_PREFIX = "/flutter"
  22
  23 FLUTTER_BUILD_ARGS = "bundle -v"
  24
  25 inherit flutter-app systemd
  26
  27 APP_CONFIG = "${BPN}.json"
  28
  29 SYSTEMD_SERVICE:${PN} = "flutter-ics-homescreen.service"
  30
  31 do_install:append() {
  32   install -D -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
  33
  34   install -D -m 0644 ${WORKDIR}/${APP_CONFIG} ${D}${datadir}/flutter/${BPN}.json
  35
  36   # VIS authorization token file for KUKSA.val should ideally not
  37   # be readable by other users, but currently that's not doable
  38   # until a packaging/sandboxing/MAC scheme is (re)implemented or
  39   # something like OAuth is plumbed in as an alternative.
  40   install -d ${D}${sysconfdir}/xdg/AGL/homescreen
  41   install -m 0644 ${WORKDIR}/ics-homescreen.yaml ${D}${sysconfdir}/xdg/AGL/
  42   install -m 0644 ${WORKDIR}/ics-homescreen.token ${D}${sysconfdir}/xdg/AGL/homescreen/
  43 }
  44
  45 FILES:${PN} += "${datadir} ${sysconfdir}/xdg/AGL"
  46 RDEPENDS:${PN} += "flutter-auto agl-flutter-env"