recipes-demo/flutter-ics-homescreen/flutter-ics-homescreen_git.bb

   1 SUMMARY = "AGL ICS Flutter Homescreen"
   2 DESCRIPTION = "Demo Flutter homescreen for Automotive Grade Linux by ICS."
   3 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/apps/flutter-ics-homescreen"
   4 SECTION = "graphics"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
   8
   9 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/flutter-ics-homescreen;protocol=https;branch=${AGL_BRANCH} \
  10   file://flutter-ics-homescreen.json \
  11   file://flutter-ics-homescreen.service \
  12   file://ics-homescreen.yaml \
  13   file://ics-homescreen.yaml.kvm-demo \
  14   file://ics-homescreen.token \
  15   file://radio-presets.yaml \
  16   file://kvm.conf \
  17 "
  18 SRCREV = "5587c6ae79b482fbff26442bb239d7d7eb55a337"
  19
  20 S = "${WORKDIR}/git"
  21
  22 PUBSPEC_APPNAME = "flutter_ics_homescreen"
  23 FLUTTER_BUILD_ARGS = "bundle -v"
  24
  25 inherit flutter-app systemd update-alternatives
  26
  27 APP_CONFIG = "${BPN}.json"
  28
  29 SYSTEMD_SERVICE:${PN} = "flutter-ics-homescreen.service"
  30
  31 # Disable the background animation on all platforms except the Renesas M3/H3 for now
  32 DISABLE_BG_ANIMATION = "-DDISABLE_BKG_ANIMATION=true"
  33 DISABLE_BG_ANIMATION:rcar-gen3 = ""
  34 APP_AOT_EXTRA:append = " ${DISABLE_BG_ANIMATION}"
  35
  36 do_install:append() {
  37     install -D -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
  38
  39     install -D -m 0644 ${WORKDIR}/kvm.conf ${D}${systemd_system_unitdir}/${BPN}.service.d/kvm.conf
  40
  41     install -D -m 0644 ${WORKDIR}/${APP_CONFIG} ${D}${datadir}/flutter/${BPN}.json
  42
  43     # VIS authorization token file for KUKSA.val should ideally not
  44     # be readable by other users, but currently that's not doable
  45     # until a packaging/sandboxing/MAC scheme is (re)implemented or
  46     # something like OAuth is plumbed in as an alternative.
  47     install -d ${D}${sysconfdir}/xdg/AGL/ics-homescreen
  48     install -m 0644 ${WORKDIR}/ics-homescreen.yaml ${D}${sysconfdir}/xdg/AGL/ics-homescreen.yaml.default
  49     install -m 0644 ${WORKDIR}/ics-homescreen.yaml.kvm-demo ${D}${sysconfdir}/xdg/AGL/
  50     install -m 0644 ${WORKDIR}/ics-homescreen.token ${D}${sysconfdir}/xdg/AGL/ics-homescreen/
  51     install -m 0644 ${WORKDIR}/radio-presets.yaml ${D}${sysconfdir}/xdg/AGL/ics-homescreen/
  52 }
  53
  54 ALTERNATIVE_LINK_NAME[ics-homescreen.yaml] = "${sysconfdir}/xdg/AGL/ics-homescreen.yaml"
  55
  56 FILES:${PN} += "${datadir} ${sysconfdir}/xdg/AGL"
  57
  58 RDEPENDS:${PN} += " \
  59     flutter-auto \
  60     agl-flutter-env \
  61     applaunchd \
  62     ${@bb.utils.contains('AGL_FEATURES', 'agl-kvm-host-audio', '', 'agl-service-radio mpd', d)} \
  63 "
  64
  65 PACKAGE_BEFORE_PN += "${PN}-conf ${PN}-conf-kvm-demo"
  66
  67 FILES:${PN}-conf += "${sysconfdir}/xdg/AGL/ics-homescreen.yaml.default"
  68 RDEPENDS:${PN}-conf = "${PN}"
  69 RPROVIDES:${PN}-conf = "ics-homescreen.yaml"
  70 RCONFLICTS:${PN}-conf = "${PN}-conf-kvm-demo"
  71 ALTERNATIVE:${PN}-conf = "ics-homescreen.yaml"
  72 ALTERNATIVE_TARGET_${PN}-conf = "${sysconfdir}/xdg/AGL/ics-homescreen.yaml.default"
  73
  74 FILES:${PN}-conf-kvm-demo += " \
  75     ${sysconfdir}/xdg/AGL/ics-homescreen.yaml.kvm-demo \
  76     ${systemd_system_unitdir}/flutter-ics-homescreen.service.d/kvm.conf \
  77 "
  78 RDEPENDS:${PN}-conf-kvm-demo = "${PN}"
  79 RPROVIDES:${PN}-conf-kvm-demo = "ics-homescreen.yaml"
  80 RCONFLICTS:${PN}-conf-kvm-demo = "${PN}-conf"
  81 ALTERNATIVE:${PN}-conf-kvm-demo = "ics-homescreen.yaml"
  82 ALTERNATIVE_TARGET_${PN}-conf-kvm-demo = "${sysconfdir}/xdg/AGL/ics-homescreen.yaml.kvm-demo"