recipes-demo/flutter-homescreen/flutter-homescreen_git.bb

   1 SUMMARY = "AGL Flutter Homescreen"
   2 DESCRIPTION = "Demo Flutter homescreen for Automotive Grade Linux."
   3 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/apps/flutter-homescreen"
   4 SECTION = "graphics"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
   8
   9 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/flutter-homescreen;protocol=https;branch=${AGL_BRANCH} \
  10            file://flutter-homescreen.json \
  11            file://flutter-homescreen.service \
  12            file://homescreen_config.yaml \
  13 "
  14 SRCREV = "5ce59ba69f1451ec18c565b7b18301856553f574"
  15
  16 S = "${WORKDIR}/git"
  17
  18 PUBSPEC_APPNAME = "flutter_homescreen"
  19 FLUTTER_APPLICATION_INSTALL_PREFIX = "/flutter"
  20
  21 FLUTTER_BUILD_ARGS = "bundle -v"
  22
  23 inherit flutter-app
  24
  25 APP_CONFIG = "flutter-homescreen.json"
  26
  27 do_install:append() {
  28     install -D -m 0644 ${WORKDIR}/flutter-homescreen.service ${D}${systemd_user_unitdir}/flutter-homescreen.service
  29     install -d ${D}${systemd_user_unitdir}/agl-session.target.wants
  30     ln -s ../flutter-homescreen.service ${D}${systemd_user_unitdir}/agl-session.target.wants/flutter-homescreen.service
  31
  32     install -D -m 0644 ${WORKDIR}/${APP_CONFIG} ${D}${datadir}/flutter/flutter-homescreen.json
  33
  34     install -d ${D}${sysconfdir}/xdg/AGL
  35     install -m 0644 ${WORKDIR}/homescreen_config.yaml ${D}${sysconfdir}/xdg/AGL/
  36 }
  37
  38 FILES:${PN} += "${datadir} ${systemd_user_unitdir} ${sysconfdir}/xdg/AGL"