recipes-demo/flutter-homescreen/flutter-homescreen_git.bb

   1 SUMMARY = "AGL Flutter Homescreen"
   2 DESCRIPTION = "Demo Flutter homescreen for Automotive Grade Linux."
   3 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/apps/flutter-homescreen"
   4 SECTION = "graphics"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
   8
   9 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/flutter-homescreen;protocol=https;branch=${AGL_BRANCH} \
  10            file://flutter-homescreen-debug.json \
  11            file://flutter-homescreen-profile.json \
  12            file://flutter-homescreen-release.json \
  13            file://flutter-homescreen.service \
  14            file://homescreen_config.yaml \
  15 "
  16 SRCREV = "5ce59ba69f1451ec18c565b7b18301856553f574"
  17
  18 S = "${WORKDIR}/git"
  19
  20 PUBSPEC_APPNAME = "flutter_homescreen"
  21 FLUTTER_APPLICATION_INSTALL_PREFIX = "/flutter"
  22
  23 FLUTTER_BUILD_ARGS = "bundle -v"
  24
  25 inherit flutter-app
  26
  27 APP_CONFIG = "flutter-homescreen-release.json"
  28 APP_CONFIG:class-runtimedebug = "flutter-homescreen-debug.json"
  29 APP_CONFIG:class-runtimeprofile = "flutter-homescreen-profile.json"
  30
  31 do_install:append() {
  32     install -D -m 0644 ${WORKDIR}/flutter-homescreen.service ${D}${systemd_user_unitdir}/flutter-homescreen.service
  33     install -d ${D}${systemd_user_unitdir}/agl-session.target.wants
  34     ln -s ../flutter-homescreen.service ${D}${systemd_user_unitdir}/agl-session.target.wants/flutter-homescreen.service
  35
  36     install -D -m 0644 ${WORKDIR}/${APP_CONFIG} ${D}${datadir}/flutter/flutter-homescreen.json
  37
  38     install -d ${D}${sysconfdir}/xdg/AGL
  39     install -m 0644 ${WORKDIR}/homescreen_config.yaml ${D}${sysconfdir}/xdg/AGL/
  40 }
  41
  42 FILES:${PN} += "${datadir} ${systemd_user_unitdir} ${sysconfdir}/xdg/AGL"