recipes-demo/flutter-dashboard/flutter-dashboard_git.bb

   1 SUMMARY = "Flutter Dashboard"
   2 DESCRIPTION = "A Flutter based IVI Dashboard Application for automotive grade Linux."
   3 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/apps/flutter-dashboard"
   4 SECTION = "graphics"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://License.md;md5=f712ede8d4f845976061925d1416fc40"
   8
   9 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/flutter-dashboard;protocol=https;branch=${AGL_BRANCH} \
  10            file://dashboard.yaml \
  11            file://dashboard.token \
  12 "
  13 SRCREV = "2fbe5f8c19863eb4ac013dce5546900592149a26"
  14
  15 S = "${WORKDIR}/git"
  16
  17 inherit agl-app flutter-app
  18
  19 # flutter-app
  20 #############
  21 PUBSPEC_APPNAME = "dashboard_app"
  22 FLUTTER_BUILD_ARGS = "bundle -v"
  23
  24 # agl-app
  25 #########
  26 AGL_APP_TEMPLATE = "agl-app-flutter"
  27 AGL_APP_ID = "dashboard_app"
  28 AGL_APP_NAME = "Dashboard"
  29
  30 do_install:append() {
  31     # VIS authorization token file for KUKSA.val should ideally not
  32     # be readable by other users, but currently that's not doable
  33     # until a packaging/sandboxing/MAC scheme is (re)implemented or
  34     # something like OAuth is plumbed in as an alternative.
  35     install -d ${D}${sysconfdir}/xdg/AGL/dashboard
  36     install -m 0644 ${WORKDIR}/dashboard.yaml ${D}${sysconfdir}/xdg/AGL/
  37     install -m 0644 ${WORKDIR}/dashboard.token ${D}${sysconfdir}/xdg/AGL/dashboard/
  38 }
  39
  40 FILES:${PN} += "${sysconfdir}/xdg/AGL"
  41 RDEPENDS:${PN} += "flutter-auto"
  42