recipes-demo/flutter-cluster-dashboard/flutter-cluster-dashboard_git.bb

   1 SUMMARY = "Flutter Instrument Cluster "
   2 DESCRIPTION = "An instrument cluster app written in dart for the flutter runtime"
   3 AUTHOR = "Aakash Solanki"
   4 HOMEPAGE = "https://github.com/aakash-s45/ic"
   5
   6 SECTION = "graphics"
   7
   8 LICENSE = "Apache-2.0"
   9 LIC_FILES_CHKSUM = "file://LICENSE.md;md5=0c52b0e4b5f0dbf57ea7d44bebb2e29d"
  10
  11 SRC_URI = "git://github.com/aakash-s45/ic;protocol=https;branch=main \
  12     file://flutter-cluster-dashboard.service \
  13     file://ic_on_bg-debug.json \
  14     file://ic_on_bg-profile.json \
  15     file://ic_on_bg-release.json \
  16 "
  17
  18 PV = "1.0+git${SRCPV}"
  19 SRCREV = "32f72bb68142a0dbde9ccf28b27c445598c95112"
  20
  21 S = "${WORKDIR}/git"
  22
  23 PUBSPEC_APPNAME = "ic"
  24
  25 FLUTTER_APPLICATION_INSTALL_PREFIX = "/flutter"
  26
  27 inherit flutter-app
  28
  29 APP_CONFIG = "ic_on_bg-release.json"
  30 APP_CONFIG:class-runtimedebug = "ic_on_bg-debug.json"
  31 APP_CONFIG:class-runtimeprofile = "ic_on_bg-profile.json"
  32
  33
  34 do_install:append() {
  35     install -D -m 0644 ${WORKDIR}/flutter-cluster-dashboard.service ${D}${systemd_user_unitdir}/flutter-cluster-dashboard.service
  36     install -d ${D}${systemd_user_unitdir}/agl-session.target.wants
  37     ln -s ../flutter-cluster-dashboard.service ${D}${systemd_user_unitdir}/agl-session.target.wants/flutter-cluster-dashboard.service
  38
  39     install -D -m 0644 ${WORKDIR}/${APP_CONFIG} ${D}${datadir}/flutter/default.json
  40 }
  41
  42
  43 FILES:${PN} += "${datadir} ${systemd_user_unitdir}"