recipes-demo/flutter-cluster-dashboard/flutter-cluster-dashboard_git.bb

   1 SUMMARY = "Flutter Instrument Cluster "
   2 DESCRIPTION = "An instrument cluster app written in dart for the flutter runtime"
   3 AUTHOR = "Aakash Solanki"
   4 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/apps/flutter-instrument-cluster"
   5
   6 SECTION = "graphics"
   7
   8 LICENSE = "Apache-2.0"
   9 LIC_FILES_CHKSUM = "file://LICENSE.md;md5=0c52b0e4b5f0dbf57ea7d44bebb2e29d"
  10
  11 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/flutter-instrument-cluster;protocol=https;branch=${AGL_BRANCH} \
  12     file://flutter-cluster-dashboard.service \
  13     file://flutter_cluster_dashboard_on_bg-debug.json \
  14     file://flutter_cluster_dashboard_on_bg-profile.json \
  15     file://flutter_cluster_dashboard_on_bg-release.json \
  16     file://flutter-cluster-dashboard.yaml \
  17 "
  18
  19 PV = "1.0+git${SRCPV}"
  20 SRCREV = "5e0cf02b4e11d67ce8b705479e13e0b9ebbf8ad4"
  21
  22 S = "${WORKDIR}/git"
  23
  24 PUBSPEC_APPNAME = "flutter_cluster_dashboard"
  25
  26 FLUTTER_APPLICATION_INSTALL_PREFIX = "/flutter"
  27
  28 OPENROUTE_API_KEY ??= "YOU_NEED_TO_SET_IT_IN_LOCAL_CONF"
  29
  30 inherit flutter-app
  31
  32 APP_CONFIG = "flutter_cluster_dashboard_on_bg-release.json"
  33 APP_CONFIG:class-runtimedebug = "flutter_cluster_dashboard_on_bg-debug.json"
  34 APP_CONFIG:class-runtimeprofile = "flutter_cluster_dashboard_on_bg-profile.json"
  35
  36
  37 do_configure:prepend() {
  38     if [ "${OPENROUTE_API_KEY}" = "YOU_NEED_TO_SET_IT_IN_LOCAL_CONF" ]; then
  39                 bbwarn "WARNING: You should set openrouteservice API key to OPENROUTE_API_KEY variable in local.conf."
  40         fi
  41 }
  42
  43 do_install:append() {
  44     install -D -m 0644 ${WORKDIR}/flutter-cluster-dashboard.service ${D}${systemd_user_unitdir}/flutter-cluster-dashboard.service
  45     install -d ${D}${systemd_user_unitdir}/agl-session.target.wants
  46     ln -s ../flutter-cluster-dashboard.service ${D}${systemd_user_unitdir}/agl-session.target.wants/flutter-cluster-dashboard.service
  47
  48     install -D -m 0644 ${WORKDIR}/${APP_CONFIG} ${D}${datadir}/flutter/default.json
  49
  50     install -d ${D}${sysconfdir}/xdg/AGL
  51     install -m 0644 ${WORKDIR}/flutter-cluster-dashboard.yaml ${D}${sysconfdir}/xdg/AGL/
  52
  53     install -m 0755 -d ${D}${sysconfdir}/default/
  54     echo 'OPENROUTE_API_KEY:${OPENROUTE_API_KEY}' >> ${D}${sysconfdir}/default/openroutekey
  55 }
  56
  57
  58 FILES:${PN} += "${datadir} ${systemd_user_unitdir} ${sysconfdir}/xdg/AGL ${sysconfdir}/default/"