recipes-demo/flutter-cluster-dashboard/flutter-cluster-dashboard_git.bb

   1 SUMMARY = "Flutter Instrument Cluster "
   2 DESCRIPTION = "An instrument cluster app written in dart for the flutter runtime"
   3 AUTHOR = "Aakash Solanki"
   4 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/apps/flutter-instrument-cluster"
   5
   6 SECTION = "graphics"
   7
   8 LICENSE = "Apache-2.0"
   9 LIC_FILES_CHKSUM = "file://LICENSE.md;md5=0c52b0e4b5f0dbf57ea7d44bebb2e29d"
  10
  11 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/flutter-instrument-cluster;protocol=https;branch=${AGL_BRANCH} \
  12     file://flutter-cluster-dashboard.service \
  13     file://flutter_cluster_dashboard_on_bg.json \
  14     file://cluster-dashboard.yaml \
  15     file://cluster-dashboard.yaml.demo \
  16     file://cluster-dashboard.token \
  17     file://kvm.conf \
  18 "
  19
  20 PV = "1.0+git${SRCPV}"
  21 SRCREV = "5bd594ae8ad92e8e74966c4ad87df83ec8088c2d"
  22
  23 S = "${WORKDIR}/git"
  24
  25 PUBSPEC_APPNAME = "flutter_cluster_dashboard"
  26
  27 inherit flutter-app update-alternatives systemd
  28
  29 CLUSTER_DEMO_VSS_HOSTNAME ??= "192.168.10.2"
  30
  31 APP_CONFIG = "flutter_cluster_dashboard_on_bg.json"
  32
  33 SYSTEMD_SERVICE:${PN} = "flutter-cluster-dashboard.service"
  34
  35 do_install:append() {
  36     install -D -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
  37
  38     install -D -m 0644 ${WORKDIR}/kvm.conf ${D}${systemd_system_unitdir}/${BPN}.service.d/kvm.conf
  39
  40     install -D -m 0644 ${WORKDIR}/${APP_CONFIG} ${D}${datadir}/flutter/${BPN}.json
  41
  42     install -d ${D}${sysconfdir}/xdg/AGL/cluster-dashboard
  43     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml ${D}${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.default
  44     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml.demo ${D}${sysconfdir}/xdg/AGL/
  45     sed -i "s/^hostname: .*/hostname: ${CLUSTER_DEMO_VSS_HOSTNAME}/" ${D}${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.demo
  46     install -m 0644 ${WORKDIR}/cluster-dashboard.token ${D}${sysconfdir}/xdg/AGL/cluster-dashboard/
  47 }
  48
  49 ALTERNATIVE_LINK_NAME[cluster-dashboard.yaml] = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml"
  50
  51 FILES:${PN} += "${datadir} ${sysconfdir}/xdg/AGL"
  52
  53 RDEPENDS:${PN} += "flutter-auto agl-flutter-env liberation-fonts"
  54
  55 PACKAGE_BEFORE_PN += "${PN}-conf ${PN}-conf-demo"
  56
  57 FILES:${PN}-conf += "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.default"
  58 RDEPENDS:${PN}-conf = "${PN}"
  59 RPROVIDES:${PN}-conf = "cluster-dashboard.yaml"
  60 RCONFLICTS:${PN}-conf = "${PN}-conf-demo"
  61 ALTERNATIVE:${PN}-conf = "cluster-dashboard.yaml"
  62 ALTERNATIVE_TARGET_${PN}-conf = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.default"
  63
  64 FILES:${PN}-conf-demo += " \
  65     ${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.demo \
  66     ${systemd_system_unitdir}/flutter-cluster-dashboard.service.d/kvm.conf \
  67 "
  68 RDEPENDS:${PN}-conf-demo = "${PN}"
  69 RPROVIDES:${PN}-conf-demo = "cluster-dashboard.yaml"
  70 RCONFLICTS:${PN}-conf-demo = "${PN}-conf"
  71 ALTERNATIVE:${PN}-conf-demo = "cluster-dashboard.yaml"
  72 ALTERNATIVE_TARGET_${PN}-conf-demo = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.demo"