recipes-demo/flutter-cluster-dashboard/flutter-cluster-dashboard_git.bb

   1 SUMMARY = "Flutter Instrument Cluster "
   2 DESCRIPTION = "An instrument cluster app written in dart for the flutter runtime"
   3 AUTHOR = "Aakash Solanki"
   4 HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/apps/flutter-instrument-cluster"
   5
   6 SECTION = "graphics"
   7
   8 LICENSE = "Apache-2.0"
   9 LIC_FILES_CHKSUM = "file://LICENSE.md;md5=0c52b0e4b5f0dbf57ea7d44bebb2e29d"
  10
  11 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/flutter-instrument-cluster;protocol=https;branch=${AGL_BRANCH} \
  12     file://flutter-cluster-dashboard.service \
  13     file://flutter_cluster_dashboard_on_bg.json \
  14     file://cluster-dashboard.yaml \
  15     file://cluster-dashboard.yaml.demo \
  16     file://cluster-dashboard.token \
  17 "
  18
  19 PV = "1.0+git${SRCPV}"
  20 SRCREV = "5bd594ae8ad92e8e74966c4ad87df83ec8088c2d"
  21
  22 S = "${WORKDIR}/git"
  23
  24 PUBSPEC_APPNAME = "flutter_cluster_dashboard"
  25
  26 FLUTTER_APPLICATION_INSTALL_PREFIX = "/flutter"
  27
  28 inherit flutter-app update-alternatives systemd
  29
  30 CLUSTER_DEMO_VISS_HOSTNAME ??= "192.168.10.2"
  31
  32 APP_CONFIG = "flutter_cluster_dashboard_on_bg.json"
  33
  34 SYSTEMD_SERVICE:${PN} = "flutter-cluster-dashboard.service"
  35
  36 do_install:append() {
  37     install -D -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
  38
  39     install -D -m 0644 ${WORKDIR}/${APP_CONFIG} ${D}${datadir}/flutter/${BPN}.json
  40
  41     install -d ${D}${sysconfdir}/xdg/AGL/cluster-dashboard
  42     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml ${D}${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.default
  43     install -m 0644 ${WORKDIR}/cluster-dashboard.yaml.demo ${D}${sysconfdir}/xdg/AGL/
  44     sed -i "s/^hostname: .*/hostname: ${CLUSTER_DEMO_VISS_HOSTNAME}/" ${D}${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.demo
  45     install -m 0644 ${WORKDIR}/cluster-dashboard.token ${D}${sysconfdir}/xdg/AGL/cluster-dashboard/
  46 }
  47
  48 ALTERNATIVE_LINK_NAME[cluster-dashboard.yaml] = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml"
  49
  50 FILES:${PN} += "${datadir} ${sysconfdir}/xdg/AGL"
  51
  52 RDEPENDS:${PN} += "flutter-auto agl-flutter-env liberation-fonts"
  53
  54 PACKAGE_BEFORE_PN += "${PN}-conf ${PN}-conf-demo"
  55
  56 FILES:${PN}-conf += "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.default"
  57 RDEPENDS:${PN}-conf = "${PN}"
  58 RPROVIDES:${PN}-conf = "cluster-dashboard.yaml"
  59 RCONFLICTS:${PN}-conf = "${PN}-conf-demo"
  60 ALTERNATIVE:${PN}-conf = "cluster-dashboard.yaml"
  61 ALTERNATIVE_TARGET_${PN}-conf = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.default"
  62
  63 FILES:${PN}-conf-demo += "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.demo"
  64 RDEPENDS:${PN}-conf-demo = "${PN}"
  65 RPROVIDES:${PN}-conf-demo = "cluster-dashboard.yaml"
  66 RCONFLICTS:${PN}-conf-demo = "${PN}-conf"
  67 ALTERNATIVE:${PN}-conf-demo = "cluster-dashboard.yaml"
  68 ALTERNATIVE_TARGET_${PN}-conf-demo = "${sysconfdir}/xdg/AGL/cluster-dashboard.yaml.demo"