recipes-demo/dashboard/dashboard_git.bb

   1 SUMMARY     = "Dashboard application"
   2 DESCRIPTION = "AGL demonstration Dashboard application"
   3 HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/dashboard"
   4 SECTION     = "apps"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
   8
   9 DEPENDS = " \
  10     qttools-native \
  11     qtquickcontrols2 \
  12     libqtappfw \
  13 "
  14
  15 PV = "2.0+git${SRCPV}"
  16
  17 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/dashboard;protocol=https;branch=${AGL_BRANCH} \
  18            file://dashboard.conf \
  19            file://dashboard.token \
  20 "
  21 SRCREV  = "ba638ce33cfac78b07c8fb69947bf6aead57d6b7"
  22
  23 S = "${WORKDIR}/git"
  24
  25 inherit qmake5 pkgconfig agl-app
  26
  27 AGL_APP_NAME = "Dashboard"
  28
  29 do_install:append() {
  30     # Currently using default global client and CA certificates
  31     # for KUKSA.val SSL, installing app specific ones would go here.
  32
  33     # VIS authorization token file for KUKSA.val should ideally not
  34     # be readable by other users, but currently that's not doable
  35     # until a packaging/sandboxing/MAC scheme is (re)implemented or
  36     # something like OAuth is plumbed in as an alternative.
  37     install -d ${D}${sysconfdir}/xdg/AGL/dashboard
  38     install -m 0644 ${WORKDIR}/dashboard.conf ${D}${sysconfdir}/xdg/AGL/
  39     install -m 0644 ${WORKDIR}/dashboard.token ${D}${sysconfdir}/xdg/AGL/dashboard/
  40 }
  41
  42 RDEPENDS:${PN} += " \
  43     qtwayland \
  44     qtbase-qmlplugins \
  45     qtgraphicaleffects-qmlplugins \
  46     qtquickcontrols2-agl-style \
  47 "