recipes-demo/cluster-receiver/cluster-receiver_git.bb

   1 SUMMARY     = "Instrument Cluster receiver application"
   2 DESCRIPTION = "AGL demonstration instrument cluster XDG remote display application"
   3 HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/agl-cluster-demo-receiver"
   4 SECTION     = "apps"
   5
   6 LICENSE     = "Apache-2.0 & MIT"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=374fee6a7817f1e1a5a7bfb7b7989553"
   8
   9 DEPENDS = " \
  10     wayland wayland-native \
  11     agl-compositor \
  12     gstreamer1.0 gstreamer1.0-plugins-base gstreamer1.0-plugins-bad \
  13 "
  14
  15 PV = "1.0+git${SRCPV}"
  16
  17 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/agl-cluster-demo-receiver;protocol=https;branch=${AGL_BRANCH} \
  18            file://cluster-receiver.service \
  19 "
  20 SRCREV  = "${AGL_APP_REVISION}"
  21
  22 S  = "${WORKDIR}/git"
  23
  24 inherit cmake pkgconfig
  25
  26 do_install:append() {
  27     install -D -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_user_unitdir}/${BPN}.service
  28     install -d ${D}${systemd_user_unitdir}/agl-session.target.wants
  29     ln -s ../${BPN}.service ${D}${systemd_user_unitdir}/agl-session.target.wants/${BPN}.service
  30 }
  31
  32 FILES:${PN} += " ${systemd_user_unitdir}"
  33
  34 RDEPENDS:${PN} += " \
  35     gstreamer1.0-plugins-base \
  36     gstreamer1.0-plugins-good \
  37     gstreamer1.0-plugins-bad \
  38 "