recipes-demo/cluster-dashboard/cluster-dashboard_git.bb

   1 SUMMARY     = "Instrument Cluster Dashboard application"
   2 DESCRIPTION = "AGL demonstration instrument cluster dashboard application"
   3 HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/agl-cluster-demo-dashboard"
   4 SECTION     = "apps"
   5
   6 LICENSE     = "Apache-2.0 & BSD-3-Clause"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984 \
   8                     file://app/cluster-gauges.qml;beginline=9;endline=48;md5=54187d50b29429abee6095fe8b7c1a78"
   9
  10 DEPENDS = " \
  11     qtquickcontrols2 \
  12     libqtappfw \
  13     glib-2.0 \
  14     wayland wayland-native \
  15     qtwayland qtwayland-native \
  16 "
  17
  18 PV = "1.0+git${SRCPV}"
  19
  20 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/agl-cluster-demo-dashboard;protocol=https;branch=${AGL_BRANCH} \
  21            file://cluster-dashboard.service \
  22 "
  23 SRCREV  = "${AGL_APP_REVISION}"
  24
  25 S  = "${WORKDIR}/git"
  26
  27 inherit pkgconfig cmake_qt5
  28
  29 do_install:append() {
  30     install -d ${D}${systemd_user_unitdir}/agl-session.target.wants
  31     install -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_user_unitdir}/${BPN}.service
  32     ln -s ../${BPN}.service ${D}${systemd_user_unitdir}/agl-session.target.wants/${BPN}.service
  33 }
  34
  35 FILES:${PN} += " ${systemd_user_unitdir}"
  36
  37 RDEPENDS:${PN} += " \
  38     qtwayland \
  39     qtbase-qmlplugins \
  40     qtquickcontrols \
  41     qtquickcontrols-qmlplugins \
  42     qtquickcontrols2 \
  43     qtquickcontrols2-qmlplugins \
  44     qtgraphicaleffects-qmlplugins \
  45     qtsvg-plugins \
  46 "