recipes-demo/agl-service-hvac/agl-service-hvac_git.bb

   1 SUMMARY     = "Demo HVAC Service Daemon"
   2 DESCRIPTION = "Demo HVAC Service Daemon"
   3 HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/agl-service-hvac"
   4
   5 LICENSE     = "Apache-2.0"
   6 LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
   7
   8 DEPENDS = "boost openssl nlohmann-json systemd"
   9
  10 SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/agl-service-hvac;protocol=https;branch=${AGL_BRANCH} \
  11            file://agl-service-hvac.conf \
  12            file://agl-service-hvac.token \
  13 "
  14 SRCREV  = "f0ac80936b73a44131564c4f65ecc0c9a9db7d39"
  15
  16 PV = "2.0+git${SRCPV}"
  17 S  = "${WORKDIR}/git"
  18
  19 inherit meson pkgconfig systemd
  20
  21 SYSTEMD_SERVICE:${PN} = "agl-service-hvac.service"
  22
  23 do_install:append() {
  24     # Currently using default global client and CA certificates
  25     # for KUKSA.val SSL, installing app specific ones would go here.
  26
  27     # VIS authorization token file for KUKSA.val should ideally not
  28     # be readable by other users, but currently that's not doable
  29     # until a packaging/sandboxing/MAC scheme is (re)implemented or
  30     # something like OAuth is plumbed in as an alternative.
  31     install -d ${D}${sysconfdir}/xdg/AGL/agl-service-hvac
  32     install -m 0644 ${WORKDIR}/agl-service-hvac.conf ${D}${sysconfdir}/xdg/AGL/
  33     install -m 0644 ${WORKDIR}/agl-service-hvac.token ${D}${sysconfdir}/xdg/AGL/agl-service-hvac/
  34 }
  35
  36 FILES:${PN} += "${systemd_system_unitdir}"
  37
  38 RDEPENDS:${PN} += "kuksa-val"