recipes-connectivity/vss/vss-agl_4.0.bb

   1 SUMMARY = "Vehicle Signal Specification with AGL overlays"
   2 LICENSE = "MPL-2.0"
   3 LIC_FILES_CHKSUM = "file://LICENSE;md5=9741c346eef56131163e13b9db1241b3"
   4
   5 DEPENDS = "vss-tools-native"
   6
   7 inherit allarch update-alternatives
   8
   9 require vss.inc
  10
  11 SRC_URI += "file://agl_vss_overlay.vspec"
  12
  13 # Since we're not relying on the simple upstream repo Makefile, use
  14 # best practices and output into a separate directory.
  15 B = "${WORKDIR}/build"
  16
  17 do_configure[noexec] = "1"
  18
  19 VSPEC2JSON_OPTS = "-e dbc -o ${WORKDIR}/agl_vss_overlay.vspec --no-uuid --json-pretty"
  20
  21 do_compile() {
  22     vspec2json.py -I ${S}/spec ${VSPEC2JSON_OPTS} -u ${S}/spec/units.yaml ${S}/spec/VehicleSignalSpecification.vspec vss_rel_${PV}-agl.json
  23 }
  24
  25 do_install() {
  26     install -d ${D}${datadir}/vss
  27     install -m 0644 vss_rel_${PV}-agl.json ${D}${datadir}/vss/
  28 }
  29
  30 ALTERNATIVE_LINK_NAME[vss.json] = "${datadir}/vss/vss.json"
  31
  32 ALTERNATIVE_PRIORITY = "20"
  33 ALTERNATIVE:${PN} = "vss.json"
  34 ALTERNATIVE_TARGET_${PN} = "${datadir}/vss/vss_rel_${PV}-agl.json"
  35
  36 FILES:${PN} += "${datadir}/vss/"