recipes-connectivity/kuksa-val/kuksa-val_git.bb

   1 SUMMARY = "KUKSA.val, the KUKSA Vehicle Abstraction Layer"
   2 DESCRIPTION = "KUKSA.val provides a COVESA VSS data model describing data in a vehicle."
   3 HOMEPAGE = "https://github.com/eclipse/kuksa.val"
   4 BUGTRACKER = "https://github.com/eclipse/kuksa.val/issues"
   5
   6 LICENSE = "Apache-2.0 & BSL-1.0 & MIT"
   7 LIC_FILES_CHKSUM = "file://../LICENSE;md5=2b42edef8fa55315f34f2370b4715ca9 \
   8                     file://3rd-party-libs/jsoncons/LICENSE;md5=6ee7f7ed2001e4cde4679fdb8926f820 \
   9                     file://3rd-party-libs/turtle/LICENSE_1_0.txt;md5=e4224ccaecb14d942c71d31bef20d78c \
  10                     file://3rd-party-libs/jwt-cpp/LICENSE;md5=8325a5ce4414c65ffdda392e0d96a9ff"
  11
  12 DEPENDS = "boost openssl mosquitto protobuf-native grpc-native grpc"
  13
  14 require kuksa-val.inc
  15
  16 SRC_URI += "file://kuksa-val.service \
  17             file://0001-Make-Boost-requirements-more-liberal.patch;striplevel=2 \
  18             file://0002-Fix-gRPC-configuration-for-OE-cross-compiling.patch;striplevel=2 \
  19             file://0003-Make-install-locations-configurable.patch;striplevel=2 \
  20             file://0004-Disable-default-fetch-and-build-of-googletest.patch;striplevel=2 \
  21             file://Server.key \
  22             file://Server.pem \
  23 "
  24 #            file://0001-genCerts.sh-add-Subject-Alt-Name-extension-to-server.patch;striplevel=? \
  25 #
  26
  27 S = "${WORKDIR}/git/kuksa-val-server"
  28
  29 inherit cmake pkgconfig systemd useradd
  30
  31 SYSTEMD_SERVICE:${PN} = "kuksa-val.service"
  32
  33 USERADD_PACKAGES = "${PN}"
  34 USERADDEXTENSION = "useradd-staticids"
  35 GROUPADD_PARAM:${PN} = "-g 900 kuksa ;"
  36 USERADD_PARAM:${PN} = "--system -g 900 -u 900 -o -d / --shell /bin/nologin kuksa ;"
  37
  38 # Configure file locations more along the lines of FHS instead of kuksa.val's
  39 # default locations.
  40 EXTRA_OECMAKE = " \
  41     -DKUKSA_INSTALL_BINDIR=${bindir} \
  42     -DKUKSA_INSTALL_CERTDIR=${sysconfdir}/kuksa-val \
  43     -DKUKSA_INSTALL_DATADIR=${datadir}/kuksa-val \
  44     -DKUKSA_INSTALL_CONFIGDIR=${sysconfdir}/kuksa-val \
  45 "
  46
  47 do_install:append() {
  48     # Lower the logging level used in the installed config.ini from the upstream
  49     # default of "ALL", which spams the logs.
  50     sed -i 's/^log-level = .*/log-level = WARNING/' ${D}/${sysconfdir}/kuksa-val/config.ini
  51
  52     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  53         install -d ${D}${systemd_system_unitdir}
  54         install -m 0644 ${WORKDIR}/kuksa-val.service ${D}${systemd_system_unitdir}
  55     fi
  56
  57     # Install replacement server key + certificate
  58     # These are AGL specific versions generated using a tweaked
  59     # genCerts.sh script from the source tree that adds the now
  60     # required subjectAltName extension field to make python3-ssl
  61     # happy.  This will be addressed with upstream and can hopefully
  62     # be dropped in the future.
  63     rm -f ${D}${sysconfdir}/kuksa-val/Server.key
  64     install ${WORKDIR}/Server.key ${D}${sysconfdir}/kuksa-val/
  65     rm -f ${D}${sysconfdir}/kuksa-val/Server.pem
  66     install ${WORKDIR}/Server.pem ${D}${sysconfdir}/kuksa-val/
  67
  68     # Restrict server certificate access
  69     # NOTE: The client certificates are left alone here for client
  70     #       development convenience for now, but this will need to
  71     #       be revisited.
  72     chmod 640 ${D}${sysconfdir}/kuksa-val/Server.key
  73     chgrp 900 ${D}${sysconfdir}/kuksa-val/Server.key
  74     chmod 640 ${D}${sysconfdir}/kuksa-val/Server.pem
  75     chgrp 900 ${D}${sysconfdir}/kuksa-val/Server.pem
  76 }
  77
  78 # Put client certificates into their own package so we can avoid
  79 # duplicates of them for e.g. cluster clients.  Longer term this
  80 # will need to be revisited.
  81 PACKAGE_BEFORE_PN += "${PN}-client-certificates"
  82
  83 FILES:${PN}-client-certificates = " \
  84     ${sysconfdir}/kuksa-val/Client.key \
  85     ${sysconfdir}/kuksa-val/Client.pem \
  86     ${sysconfdir}/kuksa-val/CA.pem \
  87 "
  88
  89 FILES:${PN} += "${systemd_system_unitdir} ${datadir}"
  90
  91 RDEPENDS:${PN} += "${PN}-client-certificates"