recipes-connectivity/kuksa-val/kuksa-dbc-feeder_git.bb

   1 SUMMARY = "DBC feeder for KUKSA.val, the KUKSA Vehicle Abstraction Layer"
   2 HOMEPAGE = "https://github.com/eclipse/kuksa.val"
   3 BUGTRACKER = "https://github.com/eclipse/kuksa.val/issues"
   4
   5 LICENSE = "Apache-2.0"
   6 LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=175792518e4ac015ab6696d16c4f607e"
   7
   8 DEPENDS = "python3-setuptools-git-versioning-native"
   9
  10 PV = "0.1.0+git${SRCPV}"
  11
  12 SRC_URI = "git://github.com/eclipse/kuksa.val.feeders.git;protocol=https;branch=main \
  13            file://0001-dbc2val-add-installation-mechanism.patch \
  14            file://0002-dbc2val-usability-improvements.patch \
  15            file://config.ini \
  16            file://dbc_feeder.json.token \
  17            file://mapping.yml \
  18            file://agl-vcar.dbc \
  19            file://kuksa-dbc-feeder.service \
  20 "
  21 SRCREV = "a857a1d6981b7d62b80ac03e60988a0bded3e255"
  22
  23 S = "${WORKDIR}/git"
  24
  25 inherit setuptools3 systemd
  26
  27 SYSTEMD_SERVICE:${PN} = "${BPN}.service"
  28
  29 do_install:append() {
  30     install -d ${D}${sysconfdir}/kuksa-dbc-feeder
  31     install -m 0644 ${WORKDIR}/config.ini ${D}${sysconfdir}/kuksa-dbc-feeder/
  32     # Token should ideally not be readable by other users.
  33     # The potential for running the feeder as non-root will take some
  34     # investigation.
  35     install -m 0600 ${WORKDIR}/dbc_feeder.json.token ${D}${sysconfdir}/kuksa-dbc-feeder/
  36     install -m 0644 ${WORKDIR}/mapping.yml ${D}${sysconfdir}/kuksa-dbc-feeder/
  37     install -m 0644 ${WORKDIR}/agl-vcar.dbc ${D}${sysconfdir}/kuksa-dbc-feeder/
  38     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  39         install -d ${D}${systemd_system_unitdir}
  40         install -m 0644 ${WORKDIR}/kuksa-dbc-feeder.service ${D}${systemd_system_unitdir}
  41     fi
  42 }
  43
  44 FILES:${PN} += "${systemd_system_unitdir}"
  45
  46 RDEPENDS:${PN} += " \
  47     bash \
  48     python3-pyserial \
  49     python3-cantools \
  50     python3-can \
  51     python3-can-j1939 \
  52     python3-pyyaml \
  53     python3-py-expression-eval \
  54     kuksa-viss-client \
  55     can-dev-helper \
  56 "