recipes-connectivity/kuksa-val/kuksa-dbc-feeder_git.bb

   1 SUMMARY = "DBC feeder for KUKSA.val, the KUKSA Vehicle Abstraction Layer"
   2 HOMEPAGE = "https://github.com/eclipse/kuksa.val"
   3 BUGTRACKER = "https://github.com/eclipse/kuksa.val/issues"
   4
   5 LICENSE = "Apache-2.0"
   6 LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=175792518e4ac015ab6696d16c4f607e"
   7
   8 DEPENDS = "python3-setuptools-git-versioning-native"
   9
  10 PV = "0.4.0+git${SRCPV}"
  11
  12 SRC_URI = "git://github.com/eclipse/kuksa.val.feeders.git;protocol=https;branch=main \
  13            file://0001-dbc2val-add-installation-mechanism.patch \
  14            file://0002-dbc2val-usability-improvements.patch \
  15            file://0003-dbc2val-fix-token-file-configuration-option.patch \
  16            file://config.ini \
  17            file://dbc_feeder.token \
  18            file://agl-vcar.dbc \
  19            file://kuksa-dbc-feeder.service \
  20            "
  21 SRCREV = "5bb52eca8d79f7c05a024f69b1faab81dabacdcd"
  22
  23 S = "${WORKDIR}/git"
  24
  25 inherit setuptools3 systemd
  26
  27 SETUPTOOLS_SETUP_PATH = "${S}/dbc2val"
  28
  29 SYSTEMD_SERVICE:${PN} = "${BPN}.service"
  30
  31 do_install:append() {
  32     install -d ${D}${sysconfdir}/kuksa-dbc-feeder
  33     install -m 0644 ${WORKDIR}/config.ini ${D}${sysconfdir}/kuksa-dbc-feeder/
  34     # Token should ideally not be readable by other users.
  35     # The potential for running the feeder as non-root will take some
  36     # investigation.
  37     install -m 0600 ${WORKDIR}/dbc_feeder.token ${D}${sysconfdir}/kuksa-dbc-feeder/
  38     install -m 0644 ${WORKDIR}/agl-vcar.dbc ${D}${sysconfdir}/kuksa-dbc-feeder/
  39     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  40         install -d ${D}${systemd_system_unitdir}
  41         install -m 0644 ${WORKDIR}/kuksa-dbc-feeder.service ${D}${systemd_system_unitdir}
  42     fi
  43 }
  44
  45 FILES:${PN} += "${systemd_system_unitdir}"
  46
  47 RDEPENDS:${PN} += " \
  48     bash \
  49     python3-pyserial \
  50     python3-cantools \
  51     python3-can \
  52     python3-can-j1939 \
  53     python3-pyyaml \
  54     python3-py-expression-eval \
  55     kuksa-client \
  56     can-dev-helper \
  57 "