recipes-connectivity/kuksa-val/kuksa-databroker_git.bb

   1 SUMMARY = "KUKSA.val databroker, the KUKSA Vehicle Abstraction Layer"
   2 #DESCRIPTION = "KUKSA.val provides a COVESA VSS data model describing data in a vehicle."
   3 HOMEPAGE = "https://github.com/eclipse/kuksa.val"
   4 BUGTRACKER = "https://github.com/eclipse/kuksa.val/issues"
   5
   6 LICENSE = "Apache-2.0"
   7 LIC_FILES_CHKSUM = "file://LICENSE;md5=2b42edef8fa55315f34f2370b4715ca9 \
   8 "
   9
  10 DEPENDS = "protobuf-native grpc-native"
  11
  12 require kuksa-val.inc
  13
  14 require ${BPN}-crates.inc
  15
  16 SRC_URI += "file://kuksa-databroker.service"
  17
  18 S = "${WORKDIR}/git"
  19
  20 inherit cargo systemd useradd
  21
  22 SYSTEMD_SERVICE:${PN} = "${BPN}.service"
  23
  24 USERADD_PACKAGES = "${PN}"
  25 USERADDEXTENSION = "useradd-staticids"
  26 GROUPADD_PARAM:${PN} = "-g 900 kuksa ;"
  27 USERADD_PARAM:${PN} = "--system -g 900 -u 900 -o -d / --shell /bin/nologin kuksa ;"
  28
  29 do_install:append() {
  30     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  31         install -d ${D}${systemd_system_unitdir}
  32         install -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}
  33     fi
  34
  35     # Install gRPC API protobuf files
  36     install -d ${D}${includedir}
  37     cp -dr ${S}/kuksa_databroker/proto/sdv ${D}${includedir}
  38 }
  39
  40 PACKAGE_BEFORE_PN += "${PN}-cli"
  41
  42 FILES:${PN} += "${systemd_system_unitdir} ${datadir}"
  43
  44 FILES:${PN}-cli = "${bindir}/databroker-cli"
  45
  46 # The upstream Cargo.toml builds optimized and stripped binaries, for
  47 # now disable the QA check as opposed to tweaking the configuration.
  48 INSANE_SKIP:${PN} = "already-stripped"
  49 INSANE_SKIP:${PN}-cli = "already-stripped"