c35c6d96bf6c7d2d2e25d13d112e4bdf98b65805
[AGL/meta-agl-demo.git] / recipes-connectivity / kuksa-val / kuksa-databroker_git.bb
1 SUMMARY = "KUKSA.val databroker, the KUKSA Vehicle Abstraction Layer"
2 #DESCRIPTION = "KUKSA.val provides a COVESA VSS data model describing data in a vehicle."
3 HOMEPAGE = "https://github.com/eclipse/kuksa.val"
4 BUGTRACKER = "https://github.com/eclipse/kuksa.val/issues"
5
6 LICENSE = "Apache-2.0"
7 LIC_FILES_CHKSUM = "file://LICENSE;md5=2b42edef8fa55315f34f2370b4715ca9 \
8 "
9  
10 DEPENDS = "protobuf-native grpc-native"
11
12 require kuksa-val.inc
13
14 require ${BPN}-crates.inc
15
16 SRC_URI += "file://0001-Force-older-clap-version-to-build-with-Rust-1.68.patch \
17             file://0002-Remove-protobuf-src-usage.patch \
18             file://kuksa-databroker.service \
19 "
20
21 S = "${WORKDIR}/git"
22
23 inherit cargo systemd useradd
24
25 # Enable optional VISS support for potential use by e.g. the web apps
26 CARGO_BUILD_FLAGS += "--features viss"
27
28 SYSTEMD_SERVICE:${PN} = "${BPN}.service"
29
30 USERADD_PACKAGES = "${PN}"
31 USERADDEXTENSION = "useradd-staticids"
32 GROUPADD_PARAM:${PN} = "-g 900 kuksa ;"
33 USERADD_PARAM:${PN} = "--system -g 900 -u 900 -o -d / --shell /bin/nologin kuksa ;"
34
35 do_install:append() {
36     if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
37         install -d ${D}${systemd_system_unitdir}
38         install -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}
39     fi
40
41     # Install gRPC API protobuf files
42     install -d ${D}${includedir}
43     cp -dr ${S}/proto/kuksa ${D}${includedir}
44     cp -dr ${S}/kuksa_databroker/proto/sdv ${D}${includedir}
45 }
46
47 PACKAGE_BEFORE_PN += "${PN}-cli"
48
49 FILES:${PN} += "${systemd_system_unitdir} ${datadir}"
50
51 FILES:${PN}-cli = "${bindir}/databroker-cli"
52
53 # The upstream Cargo.toml builds optimized and stripped binaries, for
54 # now disable the QA check as opposed to tweaking the configuration.
55 INSANE_SKIP:${PN} = "already-stripped"
56 INSANE_SKIP:${PN}-cli = "already-stripped"