recipes-connectivity/kuksa-val/kuksa-client_git.bb

   1 SUMMARY = "Python client for KUKSA.val, the KUKSA Vehicle Abstraction Layer"
   2 HOMEPAGE = "https://github.com/eclipse/kuksa.val"
   3 BUGTRACKER = "https://github.com/eclipse/kuksa.val/issues"
   4
   5 LICENSE = "Apache-2.0"
   6 LIC_FILES_CHKSUM = "file://../LICENSE;md5=2b42edef8fa55315f34f2370b4715ca9"
   7
   8 DEPENDS = " \
   9     python3-setuptools-git-versioning-native \
  10     python3-grpcio-tools-native \
  11     python3-grpcio \
  12 "
  13
  14 require kuksa-val.inc
  15
  16 SRC_URI += "file://0001-kuksa-client-Update-cmd2-completer-usage.patch;patchdir=.. \
  17             file://0002-kuksa-client-Add-external-certificates-support.patch;patchdir=.. \
  18 "
  19
  20 S = "${WORKDIR}/git/kuksa-client"
  21
  22 inherit python_setuptools_build_meta
  23
  24 RDEPENDS:${PN} += " \
  25     python3-cmd2 \
  26     python3-importlib-metadata \
  27     python3-pkg-resources \
  28     python3-pygments \
  29     python3-websockets \
  30     python3-grpcio \
  31     python3-grpcio-tools \
  32     python3-jsonpath-ng \
  33 "
  34
  35 # A script for generating new certificates currently gets shipped inside
  36 # the client module, for now add bash to RDEPENDS to quiet the QA error.
  37 # This should probably be addressed with finer-grained packaging or some
  38 # other change worked out with upstream.
  39 RDEPENDS:${PN} += "bash"