html5-mixer: recover HTML5 mixer demo application.

[AGL/meta-agl-demo.git] / recipes-demo / html5-mixer / html5-mixer_git.bb

diff --git a/recipes-demo/html5-mixer/html5-mixer_git.bb b/recipes-demo/html5-mixer/html5-mixer_git.bb
new file mode 100644 (file)
index 0000000..4a46e9b
--- /dev/null
+++ b/recipes-demo/html5-mixer/html5-mixer_git.bb
@@ -0,0 +1,42 @@
+SUMMARY     = "AGL HTML5 mixer Application"
+HOMEPAGE    = "https://git.automotivelinux.org/apps/html5-mixer/"
+SECTION     = "apps"
+LICENSE     = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
+
+PV      = "1.0+git${SRCPV}"
+S       = "${WORKDIR}/git"
+B       = "${WORKDIR}/build"
+
+SRC_URI = " \
+  git://gerrit.automotivelinux.org/gerrit/apps/html5-mixer;protocol=https;branch=master \
+  file://webapps-mixer.desktop \
+"
+SRCREV = "c189320ab6810d4c916fa8f697a9452f3a8976a4"
+
+inherit pythonnative
+
+DEPENDS = "nodejs-native"
+
+do_compile[network] = "1"
+do_compile() {
+  cd ${S}
+  rm -rf package node_modules package-lock.json
+  npm install
+  npm run build
+}
+
+WAM_APPLICATIONS_DIR="${libdir}/wam_apps"
+APPLICATIONS_DIR="${datadir}/applications"
+
+do_install() {
+  install -d ${D}${WAM_APPLICATIONS_DIR}/${PN}
+  cp -R --no-dereference --preserve=mode,links ${S}/dist/* ${D}${WAM_APPLICATIONS_DIR}/${PN}
+  install -d ${D}${APPLICATIONS_DIR}
+  install ${WORKDIR}/webapps-mixer.desktop ${D}${APPLICATIONS_DIR}
+}
+
+FILES:${PN} = " \
+  ${WAM_APPLICATIONS_DIR}/${PN} \
+  ${APPLICATIONS_DIR} \
+"