meta-agl-profile-core/recipes-platform/packagegroups/packagegroup-agl-core-boot.bb

   1 #
   2 # Copyright (C) 2007 OpenedHand Ltd.
   3 #
   4 # derived from oe-core: meta/recipes-core/packagegroups/packagegroup-core-boot.bb
   5
   6 SUMMARY = "Minimal boot requirements"
   7 DESCRIPTION = "The minimal set of packages required to boot the system"
   8 LICENSE = "MIT"
   9
  10 PACKAGE_ARCH = "${MACHINE_ARCH}"
  11
  12 inherit packagegroup
  13
  14 #
  15 # Set by the machine configuration with packages essential for device bootup
  16 #
  17 MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
  18 MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
  19
  20 # Distro can override the following VIRTUAL-RUNTIME providers:
  21 VIRTUAL-RUNTIME_dev_manager ?= "udev"
  22 VIRTUAL-RUNTIME_login_manager ?= "busybox"
  23 VIRTUAL-RUNTIME_init_manager ?= "sysvinit"
  24 VIRTUAL-RUNTIME_initscripts ?= "initscripts"
  25 VIRTUAL-RUNTIME_keymaps ?= "keymaps"
  26
  27 SYSVINIT_SCRIPTS = "${@bb.utils.contains('MACHINE_FEATURES', 'rtc', 'busybox-hwclock', '', d)} \
  28                     modutils-initscripts \
  29                     init-ifupdown \
  30                     ${VIRTUAL-RUNTIME_initscripts} \
  31                    "
  32
  33 RDEPENDS_${PN} = "\
  34     base-files \
  35     base-passwd \
  36     busybox \
  37     rng-tools \
  38     run-agl-postinsts \
  39     ${@bb.utils.contains("DISTRO_FEATURES", "sysvinit", "${SYSVINIT_SCRIPTS}", "", d)} \
  40     ${@bb.utils.contains("MACHINE_FEATURES", "keyboard", "${VIRTUAL-RUNTIME_keymaps}", "", d)} \
  41     netbase \
  42     ${VIRTUAL-RUNTIME_login_manager} \
  43     ${VIRTUAL-RUNTIME_init_manager} \
  44     ${VIRTUAL-RUNTIME_dev_manager} \
  45     ${VIRTUAL-RUNTIME_update-alternatives} \
  46     ${MACHINE_ESSENTIAL_EXTRA_RDEPENDS}"
  47
  48 RRECOMMENDS_${PN} = "\
  49     tzdata \
  50     ${MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS}"
  51