meta-agl-core/recipes-graphics/wayland/weston-ini-conf.bb

   1 SUMMARY = "Configuration file for the Weston and AGL Wayland compositors"
   2 LICENSE = "MIT"
   3 LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
   4
   5 SRC_URI = " \
   6         file://core.cfg \
   7         file://shell.cfg \
   8         file://hdmi-a-1-0.cfg \
   9         file://hdmi-a-1-90.cfg \
  10         file://hdmi-a-1-180.cfg \
  11         file://hdmi-a-1-270.cfg \
  12         file://hdmi-a-2-0.cfg \
  13         file://hdmi-a-2-90.cfg \
  14         file://hdmi-a-2-180.cfg \
  15         file://hdmi-a-2-270.cfg \
  16         file://remote-output.cfg.in \
  17         file://transmitter-output.cfg.in \
  18         file://virtual-0.cfg \
  19         file://virtual-90.cfg \
  20         file://virtual-180.cfg \
  21         file://virtual-270.cfg \
  22         file://grpc-proxy.cfg \
  23 "
  24
  25 S = "${WORKDIR}"
  26
  27 inherit update-alternatives
  28
  29 # Default primary display/orientation fragment
  30 WESTON_DISPLAYS ?= "hdmi-a-1-90"
  31
  32 # Configuration fragments to use in weston.ini.*
  33 # Note that some may be replaced/removed when building the landscape
  34 # configuration.
  35 WESTON_FRAGMENTS = "core shell grpc-proxy ${WESTON_DISPLAYS}"
  36
  37 # On-target weston.ini directory
  38 weston_ini_dir = "${sysconfdir}/xdg/weston"
  39
  40 # Options for the user to change in local.conf
  41 # e.g. TRANSMITTER_OUTPUT_MODE = "1080x1488"
  42 TRANSMITTER_OUTPUT_MODE ??= "640x720@30"
  43 TRANSMITTER_OUTPUT_HOST ??= "192.168.10.3"
  44 TRANSMITTER_OUTPUT_PORT ??= "5005"
  45
  46 do_configure() {
  47     sed -e "s#mode=.*#mode=${TRANSMITTER_OUTPUT_MODE}#" \
  48         -e "s#host=.*#host=${TRANSMITTER_OUTPUT_HOST}#" \
  49         -e "s#port=.*#port=${TRANSMITTER_OUTPUT_PORT}#" \
  50         ${WORKDIR}/transmitter-output.cfg.in  > ${WORKDIR}/transmitter-output.cfg
  51     sed -e "s#host=.*#host=${TRANSMITTER_OUTPUT_HOST}#" \
  52         -e "s#port=.*#port=${TRANSMITTER_OUTPUT_PORT}#" \
  53         ${WORKDIR}/remote-output.cfg.in  > ${WORKDIR}/remote-output.cfg
  54 }
  55
  56 do_compile() {
  57     # Put all of our cfg files together for a default portrait
  58     # orientation configuration
  59     rm -f ${WORKDIR}/weston.ini.default
  60     for F in ${WESTON_FRAGMENTS}; do
  61         cat ${WORKDIR}/${F}.cfg >> ${WORKDIR}/weston.ini.default
  62         echo >> ${WORKDIR}/weston.ini.default
  63     done
  64     sed -i -e '$ d' ${WORKDIR}/weston.ini.default
  65
  66     cat ${WORKDIR}/weston.ini.default > ${WORKDIR}/weston.ini.default-no-activate
  67
  68     # Do it again, but filter fragments to configure for landscape
  69     # and a corresponding landscape-inverted that is 180 degrees
  70     # rotated.
  71     rm -f ${WORKDIR}/weston.ini.landscape
  72     rm -f ${WORKDIR}/weston.ini.landscape-inverted
  73     for F in ${WESTON_FRAGMENTS}; do
  74         INVF=$F
  75         if echo $F | grep '^hdmi-a-1-\(90\|270\)$'; then
  76             F="hdmi-a-1-0"
  77             INVF="hdmi-a-1-180"
  78         elif echo $F | grep '^hdmi-a-2-\(90\|270\)$'; then
  79             F="hdmi-a-2-0"
  80             INVF="hdmi-a-2-180"
  81         elif echo $F | grep '^virtual-90$'; then
  82             F="virtual-0"
  83             INVF="virtual-180"
  84         fi
  85         cat ${WORKDIR}/${F}.cfg >> ${WORKDIR}/weston.ini.landscape
  86         cat ${WORKDIR}/${INVF}.cfg >> ${WORKDIR}/weston.ini.landscape-inverted
  87         echo >> ${WORKDIR}/weston.ini.landscape
  88         echo >> ${WORKDIR}/weston.ini.landscape-inverted
  89     done
  90     sed -i -e '$ d' ${WORKDIR}/weston.ini.landscape
  91     sed -i -e '$ d' ${WORKDIR}/weston.ini.landscape-inverted
  92
  93     cat ${WORKDIR}/weston.ini.landscape > ${WORKDIR}/weston.ini.landscape-no-activate
  94 }
  95
  96 do_install:append() {
  97     install -d ${D}${weston_ini_dir}
  98     install -m 0644 ${WORKDIR}/weston.ini.default ${D}${weston_ini_dir}/
  99     install -m 0644 ${WORKDIR}/weston.ini.default-no-activate ${D}${weston_ini_dir}/
 100     install -m 0644 ${WORKDIR}/weston.ini.landscape-no-activate ${D}${weston_ini_dir}/
 101     install -m 0644 ${WORKDIR}/weston.ini.landscape ${D}${weston_ini_dir}/
 102     install -m 0644 ${WORKDIR}/weston.ini.landscape-inverted ${D}${weston_ini_dir}/
 103 }
 104
 105 PACKAGE_ARCH = "${MACHINE_ARCH}"
 106
 107 # Use the alternative mechanism to handle multiple packages providing
 108 # weston.ini.  This seems simpler than other possible approaches.
 109 # Note that for now the generated packages are being marked as
 110 # incompatible with each other for simplicity, that can be changed if
 111 # a usecase where switching between alternatives at runtime is desirable
 112 # appears.
 113
 114 ALTERNATIVE_LINK_NAME[weston.ini] = "${weston_ini_dir}/weston.ini"
 115
 116 RPROVIDES:${PN} = "weston-ini"
 117 RCONFLICTS:${PN} = "${PN}-landscape"
 118 ALTERNATIVE:${PN} = "weston.ini"
 119 ALTERNATIVE_TARGET_${PN} = "${weston_ini_dir}/weston.ini.default"
 120
 121 PACKAGE_BEFORE_PN += "${PN}-landscape"
 122
 123 FILES:${PN}-landscape = "${weston_ini_dir}/weston.ini.landscape"
 124
 125 RPROVIDES:${PN}-landscape = "weston-ini"
 126 RCONFLICTS:${PN}-landscape = "${PN}"
 127 ALTERNATIVE:${PN}-landscape = "weston.ini"
 128 ALTERNATIVE_TARGET_${PN}-landscape = "${weston_ini_dir}/weston.ini.landscape"
 129
 130 PACKAGE_BEFORE_PN += "${PN}-landscape-inverted"
 131
 132 FILES:${PN}-landscape-inverted = "${weston_ini_dir}/weston.ini.landscape-inverted"
 133
 134 RPROVIDES:${PN}-landscape-inverted = "weston-ini"
 135 RCONFLICTS:${PN}-landscape-inverted = "${PN}"
 136 ALTERNATIVE:${PN}-landscape-inverted = "weston.ini"
 137 ALTERNATIVE_TARGET_${PN}-landscape-inverted = "${weston_ini_dir}/weston.ini.landscape-inverted"
 138
 139 # no activation by default
 140 PACKAGE_BEFORE_PN += "${PN}-no-activate"
 141
 142 FILES:${PN}-no-activate = "${weston_ini_dir}/weston.ini.default-no-activate"
 143
 144 RPROVIDES:${PN}-no-activate = "weston-ini"
 145 RCONFLICTS:${PN}-no-activate = "${PN}"
 146 ALTERNATIVE:${PN}-no-activate = "weston.ini"
 147 ALTERNATIVE_TARGET_${PN}-no-activate = "${weston_ini_dir}/weston.ini.default-no-activate"
 148
 149 # landscape, no activation by default
 150 PACKAGE_BEFORE_PN += "${PN}-landscape-no-activate"
 151
 152 FILES:${PN}-landscape-no-activate = "${weston_ini_dir}/weston.ini.landscape-no-activate"
 153
 154 RPROVIDES:${PN}-landscape-no-activate = "weston-ini"
 155 RCONFLICTS:${PN}-landscape-no-activate = "${PN}"
 156 ALTERNATIVE:${PN}-landscape-no-activate = "weston.ini"
 157 ALTERNATIVE_TARGET_${PN}-landscape-no-activate = "${weston_ini_dir}/weston.ini.landscape-no-activate"
 158
 159 # This is a settings-only package, we do not need a development package
 160 # (and its fixed dependency to ${PN} being installed)
 161 PACKAGES:remove = "${PN}-dev ${PN}-staticdev"