meta-agl-bsp/meta-freescale-layer/recipes-graphics/wayland/weston_2.0.0.bbappend

   1 FILESEXTRAPATHS_prepend := "${THISDIR}/weston-2.0.0:"
   2
   3 SRC_URI_append_imxgpu3d = " \
   4     file://0001-libweston-Restore-EGL-support-for-the-fbdev-backend.patch     \
   5     file://0002-MGS-2352-ccc-Add-GPU-VIV-support-for-weston-2.0.patch     \
   6     file://0006-Link-compositor-to-egl.patch                               \
   7     file://fix-ivi-layout-for-IMX6-fbdev.patch \
   8 "
   9
  10 # The 'egl' configuration of weston requires gles support, and consideration
  11 # must be taken for the different SoC capabilities:
  12 # - For SoCs with 3d support, imx-gpu-viv provides hardware-accelerated
  13 #   egl and gles, so weston egl configuration is enabled.
  14 # - For SoCs with VG2D, like i.MX 6SoloLite, imx-gpu-viv provides
  15 #   hardware-accelerated egl but does not provide a compatible software
  16 #   version of gles, so weston egl configuration is disabled.
  17 # - For SoCs with no GPU, mesa provides software implementations of egl
  18 #   and gles, so weston egl configuration is enabled.
  19 PACKAGECONFIG_IMX_TO_APPEND = ""
  20 PACKAGECONFIG_IMX_TO_APPEND_imxgpu3d = "cairo-glesv2"
  21 PACKAGECONFIG_IMX_TO_REMOVE = ""
  22 PACKAGECONFIG_IMX_TO_REMOVE_imxgpu2d = "egl"
  23 PACKAGECONFIG_IMX_TO_REMOVE_imxgpu3d = ""
  24
  25 PACKAGECONFIG_append = " ${PACKAGECONFIG_IMX_TO_APPEND}"
  26 PACKAGECONFIG_remove = " ${PACKAGECONFIG_IMX_TO_REMOVE}"
  27
  28 EXTRA_OECONF_IMX_COMMON = " \
  29     --disable-libunwind \
  30     --disable-xwayland-test \
  31     WESTON_NATIVE_BACKEND=fbdev-backend.so \
  32 "
  33 EXTRA_OECONF_IMX          = ""
  34 EXTRA_OECONF_IMX_imxpxp   = "${EXTRA_OECONF_IMX_COMMON}"
  35 EXTRA_OECONF_IMX_imxgpu2d = "${EXTRA_OECONF_IMX_COMMON}"
  36
  37 EXTRA_OECONF_append = " ${EXTRA_OECONF_IMX}"
  38
  39 PACKAGE_ARCH = "${MACHINE_SOCARCH}"