meta-agl/recipes-graphics/wayland/weston_1.9.0.bb

   1 SUMMARY = "Weston, a Wayland compositor"
   2 DESCRIPTION = "Weston is the reference implementation of a Wayland compositor"
   3 HOMEPAGE = "http://wayland.freedesktop.org"
   4 LICENSE = "MIT"
   5 LIC_FILES_CHKSUM = "file://COPYING;md5=d79ee9e66bb0f95d3386a7acae780b70 \
   6                     file://src/compositor.c;endline=26;md5=e342df749174a8ee11065583157c7a38"
   7
   8 SRC_URI = "http://wayland.freedesktop.org/releases/${BPN}-${PV}.tar.xz \
   9            file://weston.png \
  10            file://weston.desktop \
  11            file://make-lcms-explicitly-configurable.patch \
  12            file://make-libwebp-explicitly-configurable.patch \
  13            file://0001-make-error-portable.patch \
  14            file://0001-compositor-drm.c-Launch-without-input-devices.patch \
  15 "
  16 SRC_URI[md5sum] = "66bbba12f546570b4d97f676bc79a28e"
  17 SRC_URI[sha256sum] = "9c1b03f3184fa0b0dfdf67e215048085156e1a2ca344af6613fed36794ac48cf"
  18
  19 inherit autotools pkgconfig useradd
  20
  21 DEPENDS = "libxkbcommon gdk-pixbuf pixman cairo glib-2.0 jpeg"
  22 DEPENDS += "wayland libinput virtual/egl pango"
  23
  24 EXTRA_OECONF = "--enable-setuid-install \
  25                 --disable-xwayland \
  26                 --enable-simple-clients \
  27                 --enable-clients \
  28                 --enable-demo-clients-install \
  29                 --disable-rpi-compositor \
  30                 --disable-rdp-compositor \
  31                 "
  32
  33 EXTRA_OECONF_append_qemux86 = "\
  34                 WESTON_NATIVE_BACKEND=fbdev-backend.so \
  35                 "
  36 EXTRA_OECONF_append_qemux86-64 = "\
  37                 WESTON_NATIVE_BACKEND=fbdev-backend.so \
  38                 "
  39 PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'kms fbdev wayland egl', '', d)} \
  40                    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)} \
  41                    ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'launch', '', d)} \
  42                   "
  43 #
  44 # Compositor choices
  45 #
  46 # Weston on KMS
  47 PACKAGECONFIG[kms] = "--enable-drm-compositor,--disable-drm-compositor,drm udev virtual/mesa mtdev"
  48 # Weston on Wayland (nested Weston)
  49 PACKAGECONFIG[wayland] = "--enable-wayland-compositor,--disable-wayland-compositor,virtual/mesa"
  50 # Weston on X11
  51 PACKAGECONFIG[x11] = "--enable-x11-compositor,--disable-x11-compositor,virtual/libx11 libxcb libxcb libxcursor cairo"
  52 # Headless Weston
  53 PACKAGECONFIG[headless] = "--enable-headless-compositor,--disable-headless-compositor"
  54 # Weston on framebuffer
  55 PACKAGECONFIG[fbdev] = "--enable-fbdev-compositor,--disable-fbdev-compositor,udev mtdev"
  56 # weston-launch
  57 PACKAGECONFIG[launch] = "--enable-weston-launch,--disable-weston-launch,libpam drm"
  58 # VA-API desktop recorder
  59 PACKAGECONFIG[vaapi] = "--enable-vaapi-recorder,--disable-vaapi-recorder,libva"
  60 # Weston with EGL support
  61 PACKAGECONFIG[egl] = "--enable-egl --enable-simple-egl-clients,--disable-egl --disable-simple-egl-clients,virtual/egl"
  62 # Weston with cairo glesv2 support
  63 PACKAGECONFIG[cairo-glesv2] = "--with-cairo-glesv2,--with-cairo=image,cairo"
  64 # Weston with lcms support
  65 PACKAGECONFIG[lcms] = "--enable-lcms,--disable-lcms,lcms"
  66 # Weston with webp support
  67 PACKAGECONFIG[webp] = "--enable-webp,--disable-webp,libwebp"
  68 # Weston with unwinding support
  69 PACKAGECONFIG[libunwind] = "--enable-libunwind,--disable-libunwind,libunwind"
  70
  71 do_install_append() {
  72         # Weston doesn't need the .la files to load modules, so wipe them
  73         rm -f ${D}/${libdir}/weston/*.la
  74
  75         # If X11, ship a desktop file to launch it
  76         if [ "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}" = "x11" ]; then
  77                 install -d ${D}${datadir}/applications
  78                 install ${WORKDIR}/weston.desktop ${D}${datadir}/applications
  79
  80                 install -d ${D}${datadir}/icons/hicolor/48x48/apps
  81                 install ${WORKDIR}/weston.png ${D}${datadir}/icons/hicolor/48x48/apps
  82         fi
  83 }
  84
  85 PACKAGES += "${PN}-examples"
  86
  87 FILES_${PN} = "${bindir}/weston ${bindir}/weston-terminal ${bindir}/weston-info ${bindir}/weston-launch ${bindir}/wcap-decode ${libexecdir} ${libdir}/${BPN}/*.so ${datadir}"
  88 FILES_${PN}-examples = "${bindir}/*"
  89
  90 RDEPENDS_${PN} += "xkeyboard-config"
  91 RRECOMMENDS_${PN} = "liberation-fonts"
  92
  93 USERADD_PACKAGES = "${PN}"
  94 GROUPADD_PARAM_${PN} = "--system weston-launch"