wlproto(IVI_CON ivi-controller)

include(FindPkgConfig)
pkg_check_modules(AFB REQUIRED afb-daemon==1.0)
pkg_check_modules(SD REQUIRED libsystemd>=222)

# We do not want a prefix for our module
set(CMAKE_SHARED_MODULE_PREFIX "")

add_library(winman MODULE
   main.cpp
   wayland.cpp
   wayland.hpp
   util.cpp
   util.hpp
   ${IVI_CON_PROTO} json_helper.cpp json_helper.hpp app.hpp app.cpp)

target_include_directories(winman
    PRIVATE
        ${AFB_INCLUDE_DIRS}
        ${SD_INCLUDE_DIRS}
        ../include)

target_link_libraries(winman
    PRIVATE
        ${AFB_LIBRARIES}
        ${WLC_LIBRARIES}
        ${SD_LIBRARIES})

target_compile_definitions(winman
    PRIVATE
        AFB_BINDING_VERSION=2
        # We do not want source location of messages
        AFB_BINDING_PRAGMA_NO_VERBOSE_DETAILS
        WINMAN_VERSION_STRING="${PACKAGE_VERSION}"
        _GNU_SOURCE)  # XXX should I define this here?!

if(NOT ${CMAKE_BUILD_TYPE} STREQUAL "Release")
   target_compile_definitions(winman
       PRIVATE
           _GLIBCXX_DEBUG)
endif()

target_compile_options(winman
    PRIVATE
        -Wall -Wextra -Wno-unused-parameter -Wno-comment)

set_target_properties(winman
    PROPERTIES
        INTERPROCEDURAL_OPTIMIZATION ON

        CXX_EXTENSIONS OFF
        CXX_STANDARD 14
        CXX_STANDARD_REQUIRED ON

        C_EXTENSIONS OFF
        C_STANDARD 99
        C_STANDARD_REQUIRED ON

        LINK_FLAGS "-Wl,--version-script=../../export.map")

if (NOT ${SANITIZER_MODE} STREQUAL "none" AND NOT ${SANITIZER_MODE} STREQUAL "")
   target_compile_options(winman
      PRIVATE
         -fsanitize=${SANITIZER_MODE} -g -fno-omit-frame-pointer)
   set_target_properties(winman
      PROPERTIES
         LINK_FLAGS "-fsanitize=${SANITIZER_MODE} -g")
endif()