From: Marius Vlad <marius.vlad@collabora.com>
Date: Thu, 30 Jan 2025 15:33:41 +0000 (+0200)
Subject: uhmi-agl-wm: Add basic recipe for uhmi-agl-wm
X-Git-Url: https://gerrit.automotivelinux.org/gerrit/gitweb?a=commitdiff_plain;h=refs%2Fchanges%2F91%2F30791%2F2;p=AGL%2Fmeta-agl-devel.git

uhmi-agl-wm: Add basic recipe for uhmi-agl-wm

This is the equivalent to uhmi-ivi-wm, but rather tailored for the AGL
compositor.

Bug-AGL: SPEC-5280
Change-Id: I84da010e41a19face78d6fb08efbaf6a0088e6a4
Signed-off-by: Marius Vlad <marius.vlad@collabora.com>
---

diff --git a/meta-uhmi/recipes-core/uhmi-agl-wm/files/uhmi-agl-wm.service b/meta-uhmi/recipes-core/uhmi-agl-wm/files/uhmi-agl-wm.service
new file mode 100644
index 00000000..7e8d4d3f
--- /dev/null
+++ b/meta-uhmi/recipes-core/uhmi-agl-wm/files/uhmi-agl-wm.service
@@ -0,0 +1,15 @@
+[Unit]
+Description=uhmi AGL window manager
+After=agl-compositor.service
+
+[Service]
+EnvironmentFile=-/etc/default/uhmi-agl-wm
+
+Type=simple
+ExecStart=/usr/bin/uhmi-agl-wm
+KillSignal=SIGKILL
+Restart=always
+RestartSec=1s
+
+[Install]
+WantedBy=multi-user.target
diff --git a/meta-uhmi/recipes-core/uhmi-agl-wm/uhmi-agl-wm_git.bb b/meta-uhmi/recipes-core/uhmi-agl-wm/uhmi-agl-wm_git.bb
new file mode 100644
index 00000000..f1aab6af
--- /dev/null
+++ b/meta-uhmi/recipes-core/uhmi-agl-wm/uhmi-agl-wm_git.bb
@@ -0,0 +1,41 @@
+DESCRIPTION = "UHMI AGL window-manager"
+DEPENDS = " agl-compositor grpc grpc-native jansson"
+
+RDEPENDS:${PN} = " jansson"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=fb8ec92f12228c45a207d99abba9d6c9"
+
+FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
+
+PN="uhmi-agl-wm"
+
+SRCREV = "332c9f0b5fa2e2ee91d7f12331621a63759b6ae0"
+BRANCH ?= "master"
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/uhmi-agl-wm.git;protocol=https;branch=${AGL_BRANCH}"
+PV = "0.0+git${SRCPV}"
+
+S = "${WORKDIR}/git"
+
+inherit meson pkgconfig systemd features_check
+
+SRC_URI += " file://uhmi-agl-wm.service"
+
+REQUIRED_DISTRO_FEATURES = "systemd"
+SYSTEMD_PACKAGES = "${PN}"
+SYSTEMD_SERVICE:${PN} = "uhmi-agl-wm.service"
+SYSTEMD_AUTO_ENABLE:${PN} = "enable"
+
+FILES:${PN} += " \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '${systemd_system_unitdir}/${SYSTEMD_SERVICE}', '', d)} \
+    "
+
+do_install:append() {
+    if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
+	install -d ${D}${systemd_system_unitdir}
+	install -m 644 ${WORKDIR}/*.service ${D}/${systemd_system_unitdir}
+    fi
+}
+
+FILES:${PN} += " /usr/bin/uhmi-agl-wm"
+FILES:${PN} += " /usr/share/*"