From: Scott Murray <scott.murray@konsulko.com>
Date: Thu, 16 Jun 2022 04:48:55 +0000 (-0400)
Subject: agl-service-hvac: add updated recipes
X-Git-Tag: 13.91.0~9
X-Git-Url: https://gerrit.automotivelinux.org/gerrit/gitweb?a=commitdiff_plain;h=26144b14060e8532c8d4e8ad5c59161f41ccd076;p=AGL%2Fmeta-agl-demo.git

agl-service-hvac: add updated recipes

Add recipes to build the new incarnation of VIS client daemon version
of agl-service-hvac and for installing associated demo platform
configuration files for the full AGL demo setup.  As well, add the
new packages from these recipes to the appropriate packagegroups.

Bug-AGL: SPEC-4409

Signed-off-by: Scott Murray <scott.murray@konsulko.com>
Change-Id: I34fae0a6e2c3ed387757eb01a9c8042ba14fbd0f
---

diff --git a/recipes-demo/agl-service-hvac/agl-service-hvac-demo-conf.bb b/recipes-demo/agl-service-hvac/agl-service-hvac-demo-conf.bb
new file mode 100644
index 000000000..75987905a
--- /dev/null
+++ b/recipes-demo/agl-service-hvac/agl-service-hvac-demo-conf.bb
@@ -0,0 +1,31 @@
+SUMMARY     = "AGL demo configuration for HVAC service daemon"
+HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/agl-service-hvac"
+SECTION     = "apps"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+SRC_URI = "file://agl-service-hvac-can.conf.demo \
+           file://sllin.conf \
+"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+do_configure[noexec] = "1"
+do_compile[noexec] = "1"
+
+do_install () {
+    # Install configuration file to use sllin0 instead of the default
+    # can0 CAN device.
+    install -D -m 644 ${WORKDIR}/agl-service-hvac-can.conf.demo ${D}${sysconfdir}/xdg/AGL/agl-service-hvac-can.conf
+
+    # Install systemd override to add a dependency on kuksa-dbc-feeder-sllin.service,
+    # which currently brings up sllin0.  This will need to be reworked in the future
+    # to be a bit more straightforward.
+    install -d ${D}${systemd_system_unitdir}/agl-service-hvac.service.d
+    install -m 0644 ${WORKDIR}/sllin.conf ${D}${systemd_system_unitdir}/agl-service-hvac.service.d/
+}
+
+FILES:${PN} += "${systemd_system_unitdir}"
+
+RDEPENDS:${PN} += "agl-service-hvac kuksa-dbc-feeder-sllin"
diff --git a/recipes-demo/agl-service-hvac/agl-service-hvac-demo-conf/agl-service-hvac-can.conf.demo b/recipes-demo/agl-service-hvac/agl-service-hvac-demo-conf/agl-service-hvac-can.conf.demo
new file mode 100644
index 000000000..d2e0bb3d4
--- /dev/null
+++ b/recipes-demo/agl-service-hvac/agl-service-hvac-demo-conf/agl-service-hvac-can.conf.demo
@@ -0,0 +1,2 @@
+[can]
+port = "sllin0"
diff --git a/recipes-demo/agl-service-hvac/agl-service-hvac-demo-conf/sllin.conf b/recipes-demo/agl-service-hvac/agl-service-hvac-demo-conf/sllin.conf
new file mode 100644
index 000000000..f4df1855b
--- /dev/null
+++ b/recipes-demo/agl-service-hvac/agl-service-hvac-demo-conf/sllin.conf
@@ -0,0 +1,3 @@
+[Unit]
+Requires=kuksa-dbc-feeder-sllin.service
+After=kuksa-dbc-feeder-sllin.service
diff --git a/recipes-demo/agl-service-hvac/agl-service-hvac/agl-service-hvac.conf b/recipes-demo/agl-service-hvac/agl-service-hvac/agl-service-hvac.conf
new file mode 100644
index 000000000..31f22ff72
--- /dev/null
+++ b/recipes-demo/agl-service-hvac/agl-service-hvac/agl-service-hvac.conf
@@ -0,0 +1,2 @@
+[vis-client]
+authorization = "/etc/xdg/AGL/agl-service-hvac/agl-service-hvac.token"
diff --git a/recipes-demo/agl-service-hvac/agl-service-hvac/agl-service-hvac.token b/recipes-demo/agl-service-hvac/agl-service-hvac/agl-service-hvac.token
new file mode 100644
index 000000000..770aadcff
--- /dev/null
+++ b/recipes-demo/agl-service-hvac/agl-service-hvac/agl-service-hvac.token
@@ -0,0 +1 @@
+eyJ0eXAiOiJKV1QiLCJhbGciOiJSUzI1NiJ9.eyJzdWIiOiJrdWtzYS52YWwiLCJpc3MiOiJFY2xpcHNlIEtVS1NBIERldiIsImFkbWluIjp0cnVlLCJpYXQiOjE1MTYyMzkwMjIsImV4cCI6MTc2NzIyNTU5OSwia3Vrc2EtdnNzIjp7IioiOiJydyJ9fQ.QQcVR0RuRJIoasPXYsMGZhdvhLjUalk4GcRaxhh3-0_j3CtVSZ0lTbv_Z3As5BfIYzaMlwUzFGvCVOq2MXVjRK81XOAZ6wIsyKOxva16zjbZryr2V_m3yZ4twI3CPEzJch11_qnhInirHltej-tGg6ySfLaTYeAkw4xYGwENMBBhN5t9odANpScZP_xx5bNfwdW1so6FkV1WhpKlCywoxk_vYZxo187d89bbiu-xOZUa5D-ycFkd1-1rjPXLGE_g5bc4jcQBvNBc-5FDbvt4aJlTQqjpdeppxhxn_gjkPGIAacYDI7szOLC-WYajTStbksUju1iQCyli11kPx0E66me_ZVwOX07f1lRF6D2brWm1LcMAHM3bQUK0LuyVwWPxld64uSAEsvSKsRyJERc7nZUgLf7COnUrrkxgIUNjukbdT2JVN_I-3l3b4YXg6JVD7Y5g0QYBKgXEFpZrDbBVhzo7PXPAhJD6-c3DcUQyRZExbrnFV56RwWuExphw8lYnbMvxPWImiVmB9nRVgFKD0TYaw1sidPSSlZt8Uw34VZzHWIZQAQY0BMjR33fefg42XQ1YzIwPmDx4GYXLl7HNIIVbsRsibKaJnf49mz2qnLC1K272zXSPljO11Ke1MNnsnKyUH7mcwEs9nhTsnMgEOx_TyMLRYo-VEHBDLuEOiBo
\ No newline at end of file
diff --git a/recipes-demo/agl-service-hvac/agl-service-hvac_git.bb b/recipes-demo/agl-service-hvac/agl-service-hvac_git.bb
new file mode 100644
index 000000000..094a1b528
--- /dev/null
+++ b/recipes-demo/agl-service-hvac/agl-service-hvac_git.bb
@@ -0,0 +1,38 @@
+SUMMARY     = "Demo HVAC Service Daemon"
+DESCRIPTION = "Demo HVAC Service Daemon"
+HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/agl-service-hvac"
+
+LICENSE     = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
+
+DEPENDS = "boost openssl nlohmann-json systemd"
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/agl-service-hvac;protocol=https;branch=${AGL_BRANCH} \
+           file://agl-service-hvac.conf \
+           file://agl-service-hvac.token \
+"
+SRCREV  = "096908375ecbfc6388d0aec69a35b2a8ffc53d47"
+
+PV = "2.0+git${SRCPV}"
+S  = "${WORKDIR}/git"
+
+inherit meson pkgconfig systemd
+
+SYSTEMD_SERVICE:${PN} = "agl-service-hvac.service"
+
+do_install:append() {
+    # Currently using default global client and CA certificates
+    # for KUKSA.val SSL, installing app specific ones would go here.
+
+    # VIS authorization token file for KUKSA.val should ideally not
+    # be readable by other users, but currently that's not doable
+    # until a packaging/sandboxing/MAC scheme is (re)implemented or
+    # something like OAuth is plumbed in as an alternative.
+    install -d ${D}${sysconfdir}/xdg/AGL/agl-service-hvac
+    install -m 0644 ${WORKDIR}/agl-service-hvac.conf ${D}${sysconfdir}/xdg/AGL/
+    install -m 0644 ${WORKDIR}/agl-service-hvac.token ${D}${sysconfdir}/xdg/AGL/agl-service-hvac/
+}
+
+FILES:${PN} += "${systemd_system_unitdir}"
+
+RDEPENDS:${PN} += "kuksa-val"
diff --git a/recipes-platform/packagegroups/packagegroup-agl-demo-preload.bb b/recipes-platform/packagegroups/packagegroup-agl-demo-preload.bb
index 25a379508..317b90052 100644
--- a/recipes-platform/packagegroups/packagegroup-agl-demo-preload.bb
+++ b/recipes-platform/packagegroups/packagegroup-agl-demo-preload.bb
@@ -9,7 +9,7 @@ PACKAGES = " \
 "
 
 # NOTES:
-# - demo-i2x-udev-conf:
+# - demo-i2c-udev-conf:
 #     Adds udev configuration and scripts for supporting USB attached
 #     I2C devices for RTC and HVAC LED support.
 # - sllin-demo:
@@ -20,6 +20,9 @@ PACKAGES = " \
 #     Adds configuration and systemd unit to run a second instance of
 #     the DBC feeder against the sllin0 interface to connect the
 #     steering wheel controls into VIS.
+# - agl-service-hvac-demo-conf:
+#     Adds configuration to make agl-service-hvac use sllin0 for its
+#     HVAC board control via CAN -> LIN.
 # - simple-can-simulator:
 #     CAN message simulator for vehicle and engine speed message
 #     generation, with some support for the cruise control events from
@@ -30,5 +33,6 @@ RDEPENDS:${PN} = "\
     demo-i2c-udev-conf \
     sllin-demo \
     kuksa-dbc-feeder-sllin \
+    agl-service-hvac-demo-conf \
     simple-can-simulator \
 "
diff --git a/recipes-platform/packagegroups/packagegroup-agl-ivi-services.bb b/recipes-platform/packagegroups/packagegroup-agl-ivi-services.bb
index d9e691bf7..7646ccf38 100644
--- a/recipes-platform/packagegroups/packagegroup-agl-ivi-services.bb
+++ b/recipes-platform/packagegroups/packagegroup-agl-ivi-services.bb
@@ -11,4 +11,5 @@ RDEPENDS:${PN} += "\
     kuksa-val \
     kuksa-val-agl \
     kuksa-dbc-feeder \
+    agl-service-hvac \
     "