From: Scott Murray <scott.murray@konsulko.com>
Date: Thu, 29 Aug 2019 22:05:05 +0000 (-0400)
Subject: meta-agl-profile-cluster-qt5: Add qtcompositor-conf recipe
X-Git-Tag: halibut_8.0.1~3
X-Git-Url: https://gerrit.automotivelinux.org/gerrit/gitweb?a=commitdiff_plain;h=19ae581068d953ae0339a47ee0e12b082f85f25a;p=AGL%2Fmeta-agl.git

meta-agl-profile-cluster-qt5: Add qtcompositor-conf recipe

Add qtcompositor-conf recipe to create the udev rule files required to
set up the "display" group ownership of graphics devices when not using
weston.  The recipe is based on what is done in the weston-init bbappend
in the meta-agl-profile-graphical layer.  The package is also added to
the agl-profile-cluster-qtcompositor packagegroup so that the qtcompositor
cluster demo image will pick it up.

Bug-AGL: SPEC-2775

Change-Id: I375e915b2074eb2abcec534a88fddfc6445730e1
Signed-off-by: Scott Murray <scott.murray@konsulko.com>
---

diff --git a/meta-agl-profile-cluster-qt5/recipes-platform/packagegroups/packagegroup-agl-profile-cluster-qtcompositor.bb b/meta-agl-profile-cluster-qt5/recipes-platform/packagegroups/packagegroup-agl-profile-cluster-qtcompositor.bb
index 31280bb20..9d54b33a4 100644
--- a/meta-agl-profile-cluster-qt5/recipes-platform/packagegroups/packagegroup-agl-profile-cluster-qtcompositor.bb
+++ b/meta-agl-profile-cluster-qt5/recipes-platform/packagegroups/packagegroup-agl-profile-cluster-qtcompositor.bb
@@ -25,6 +25,7 @@ QT_LITE = " \
     qtsvg-plugins \
     qtwebsockets \
     qtwebsockets-qmlplugins \
+    qtcompositor-conf \
 "
 
 RDEPENDS_${PN}_append = " \
diff --git a/meta-agl-profile-cluster-qt5/recipes-qt/qt5/qtcompositor-conf_1.0.bb b/meta-agl-profile-cluster-qt5/recipes-qt/qt5/qtcompositor-conf_1.0.bb
new file mode 100644
index 000000000..49111b6e8
--- /dev/null
+++ b/meta-agl-profile-cluster-qt5/recipes-qt/qt5/qtcompositor-conf_1.0.bb
@@ -0,0 +1,40 @@
+SUMMARY = "Configuration files for running wayland with a non-weston compositor"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+inherit allarch agl-graphical
+
+do_configure[noexec] = "1"
+do_compile[noexec] = "1"
+
+do_install() {
+    # Add a rule to ensure the 'display' user has permissions to
+    # open the graphics device
+    install -d ${D}${sysconfdir}/udev/rules.d
+    cat >${D}${sysconfdir}/udev/rules.d/zz-dri.rules <<'EOF'
+SUBSYSTEM=="drm", MODE="0660", GROUP="${WESTONGROUP}", SECLABEL{smack}="*"
+EOF
+
+    # user 'display' must also be able to access /dev/input/*
+    cat >${D}${sysconfdir}/udev/rules.d/zz-input.rules <<'EOF'
+SUBSYSTEM=="input", MODE="0660", GROUP="input", SECLABEL{smack}="^"
+EOF
+
+    # user 'display' must also be able to access /dev/media*, etc.
+    cat >${D}${sysconfdir}/udev/rules.d/zz-remote-display.rules <<'EOF'
+SUBSYSTEM=="media", MODE="0660", GROUP="display", SECLABEL{smack}="*"
+SUBSYSTEM=="video4linux", MODE="0660", GROUP="display", SECLABEL{smack}="*"
+KERNEL=="uvcs", SUBSYSTEM=="misc", MODE="0660", GROUP="display", SECLABEL{smack}="*"
+KERNEL=="rgnmm", SUBSYSTEM=="misc", MODE="0660", GROUP="display", SECLABEL{smack}="*"
+EOF
+}
+
+do_install_append_imx() {
+    install -d ${D}${sysconfdir}/udev/rules.d
+    cat >>${D}${sysconfdir}/udev/rules.d/zz-dri.rules <<'EOF'
+SUBSYSTEM=="gpu_class", MODE="0660", GROUP="${WESTONGROUP}", SECLABEL{smack}="*"
+EOF
+
+}
+
+RCONFLICTS_${PN} = "weston-init"