Add recipes for voice agent service and app

Recipe files to compile the voice agent service and the flutter
app, also add meta-tensorflow layer conf.

Bug-AGL: SPEC-4906
Change-Id: I0e2eea863c95cd84d85d06194fbf01fcc64adb86
Signed-off-by: Malik Talha <talhamalik727x@gmail.com>

diff --git a/meta-offline-voice-agent/recipes-assistant/voiceagent-app/agl-flutter-voiceassistant_git.bb b/meta-offline-voice-agent/recipes-assistant/voiceagent-app/agl-flutter-voiceassistant_git.bb
new file mode 100644 (file)
index 0000000..036e1fe
--- /dev/null
+++ b/meta-offline-voice-agent/recipes-assistant/voiceagent-app/agl-flutter-voiceassistant_git.bb
@@ -0,0 +1,27 @@
+SUMMARY = "AGL Voice Assistant"
+DESCRIPTION = "Offline voice assistant app designed for Automotive Grade Linux (AGL)."
+HOMEPAGE = "https://github.com/malik727/agl-flutter-voiceassistant"
+BUGTRACKER = "https://github.com/malik727/agl-flutter-voiceassistant/issues"
+SECTION = "graphics"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=4202492ed9afcab3aaecc4a9ec32adb2"
+
+SRC_URI = "git://github.com/malik727/agl-flutter-voiceassistant.git;protocol=https;branch=main \
+    "
+    
+SRCREV = "${AUTOREV}"
+S = "${WORKDIR}/git"
+
+inherit agl-app flutter-app
+
+# flutter-app
+#############
+PUBSPEC_APPNAME = "agl_flutter_voiceassistant"
+FLUTTER_APPLICATION_INSTALL_PREFIX = "/flutter"
+FLUTTER_BUILD_ARGS = "bundle -v"
+
+# agl-app
+#########
+AGL_APP_TEMPLATE = "agl-app-flutter"
+AGL_APP_ID = "agl_flutter_voiceassistant"
+AGL_APP_NAME = "AGL Voice Assistant"
\ No newline at end of file

diff --git a/meta-offline-voice-agent/recipes-assistant/voiceagent-service/agl-service-voiceagent_git.bb b/meta-offline-voice-agent/recipes-assistant/voiceagent-service/agl-service-voiceagent_git.bb
new file mode 100644 (file)
index 0000000..615ec64
--- /dev/null
+++ b/meta-offline-voice-agent/recipes-assistant/voiceagent-service/agl-service-voiceagent_git.bb
@@ -0,0 +1,35 @@
+SUMMARY = "A gRPC-based voice agent service designed for Automotive Grade Linux (AGL)."
+HOMEPAGE = "https://github.com/malik727/agl-service-voiceagent"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=4202492ed9afcab3aaecc4a9ec32adb2"
+
+SRC_URI = " \
+    git://github.com/malik727/agl-service-voiceagent;protocol=https;branch=main \
+"
+
+SRCREV = "${AUTOREV}"
+S = "${WORKDIR}/git"
+
+DEPENDS += " \
+    python3 \
+    python3-setuptools-native \
+    python3-grpcio-tools-native \
+    "
+
+inherit setuptools3
+
+do_compile:prepend() {
+    # Generate proto files and move them to 'generated/' directory
+    python3 -m grpc_tools.protoc -I${S}/agl_service_voiceagent/protos --python_out=${S}/agl_service_voiceagent/generated --grpc_python_out=${S}/agl_service_voiceagent/generated voice_agent.proto
+}
+
+RDEPENDS:${PN} += " \
+    python3-numpy \
+    python3-grpcio \
+    python3-grpcio-tools \
+    python3-pygobject \
+    kuksa-client \
+    python3-rasa \
+    python3-snips-inference-agl \
+    vosk \
+    "

diff --git a/templates/feature/agl-offline-voice-agent/50_bblayers.conf.inc b/templates/feature/agl-offline-voice-agent/50_bblayers.conf.inc
index f46f44f..ef9d57d 100644 (file)
--- a/templates/feature/agl-offline-voice-agent/50_bblayers.conf.inc
+++ b/templates/feature/agl-offline-voice-agent/50_bblayers.conf.inc
@@ -4,4 +4,5 @@ AGL_META_PYTHON = "${METADIR}/external/meta-openembedded/meta-python"
 
 BBLAYERS =+ " \
     ${METADIR}/meta-agl-devel/meta-offline-voice-agent \
+    ${METADIR}/external/meta-tensorflow \
 "