Add a shrink agl-demo-platform version

Base on agl-demo-platform, make a shrink version for low performance
board can run agl-demo-platform.
Weston, hmi-framework, some APPs and some services were deleted.
Using cluster-dashboard as qtwayland compositor instead of weston.

Bug-AGL: SPEC-2487

Signed-off-by: Ouyang Jun <ouyangj.fnst@cn.fujitsu.com>
Signed-off-by: Zhou Mingying <zhoumy@cn.fujitsu.com>
Signed-off-by: Liu Wenlong <liuwl.fnst@cn.fujitsu.com>
Change-Id: I96bb337f6ae157f696fc2e4fb61cdd7afc8f5109

diff --git a/README.md b/README.md
index ea133e3..3c75723 100644 (file)
--- a/README.md
+++ b/README.md
@@ -80,6 +80,10 @@ contains only ``packagegroup-agl-cluster-demo-platform``.
 ``packagegroup-agl-profile-cluster-qt5``, and the packages required for the DEMO
 applications.
 
+* packagegroup-agl-cluster-demo-qtcompositor
+
+This is for generating the image 'agl-cluster-demo-qtcompositor'.
+
 Supported Machines
 ------------------
 
@@ -95,3 +99,6 @@ Supported Target of bitbake
 * `agl-cluster-demo-platform` is the full image of the AGL Instrument Cluster
 Demo Platform with all applications
 
+* `agl-cluster-demo-qtcompositor` is the image of the AGL Instrument Cluster
+Demo that uses qtwayland compositor, contains a simple cluster graphic user
+interface and some AGL services.

diff --git a/recipes-demo-hmi/cluster-gauges-qtcompositor/cluster-gauges-qtcompositor_git.bb b/recipes-demo-hmi/cluster-gauges-qtcompositor/cluster-gauges-qtcompositor_git.bb
new file mode 100644 (file)
index 0000000..44feecb
--- /dev/null
+++ b/recipes-demo-hmi/cluster-gauges-qtcompositor/cluster-gauges-qtcompositor_git.bb
@@ -0,0 +1,29 @@
+SUMMARY     = "Minimal cluster demo gauges that can be used standalone"
+DESCRIPTION = "AGL HMI Application for demonstrating instrument cluster gauges as a wayland compositor"
+HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/agl-cluster-demo-gauges"
+SECTION     = "apps"
+
+LICENSE     = "Apache-2.0 & BSD"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984 \
+                    file://app/cluster-gauges.qml;beginline=10;endline=49;md5=54187d50b29429abee6095fe8b7c1a78"
+
+SRC_URI = "gitsm://gerrit.automotivelinux.org/gerrit/apps/agl-cluster-demo-gauges;protocol=https;branch=${AGL_BRANCH}"
+SRCREV  = "${AGL_APP_REVISION}"
+
+PV = "1.0+git${SRCPV}"
+S  = "${WORKDIR}/git"
+
+# build-time dependencies
+DEPENDS += "qtquickcontrols2 qtwebsockets"
+
+inherit pkgconfig cmake_qt5 aglwgt
+
+RDEPENDS_${PN} += " \
+       qtquickcontrols \
+       qtquickcontrols-qmlplugins \
+       qtquickcontrols2 \
+       qtquickcontrols2-qmlplugins \
+       qtwebsockets \
+       qtwebsockets-qmlplugins \
+       kms-conf \
+"

diff --git a/recipes-graphics/kms-conf/kms-conf/kms.conf b/recipes-graphics/kms-conf/kms-conf/kms.conf
new file mode 100644 (file)
index 0000000..7fa9686
--- /dev/null
+++ b/recipes-graphics/kms-conf/kms-conf/kms.conf
@@ -0,0 +1,8 @@
+{
+    "device": "/dev/dri/card0",
+    "outputs": [
+      {
+        "name":"HDMI-A-1"
+      }
+    ]
+}

diff --git a/recipes-graphics/kms-conf/kms-conf/m3ulcb/kms.conf b/recipes-graphics/kms-conf/kms-conf/m3ulcb/kms.conf
new file mode 100644 (file)
index 0000000..16ea328
--- /dev/null
+++ b/recipes-graphics/kms-conf/kms-conf/m3ulcb/kms.conf
@@ -0,0 +1,12 @@
+{
+    "device": "/dev/dri/card0",
+    "outputs": [
+      {
+        "name":"HDMI-A-1"
+      },
+      {
+        "name":"LVDS1",
+        "mode":"off"
+      }
+    ]
+}

diff --git a/recipes-graphics/kms-conf/kms-conf_1.0.bb b/recipes-graphics/kms-conf/kms-conf_1.0.bb
new file mode 100644 (file)
index 0000000..b063f65
--- /dev/null
+++ b/recipes-graphics/kms-conf/kms-conf_1.0.bb
@@ -0,0 +1,12 @@
+SUMMARY = "kms configuration file for the qt eglfs platform"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
+
+SRC_URI = " \
+    file://kms.conf \
+"
+
+do_install_append() {
+    install -d ${D}/etc
+    install -m 644 ${WORKDIR}/kms.conf ${D}/etc
+}

diff --git a/recipes-platform/images/agl-cluster-demo-qtcompositor.bb b/recipes-platform/images/agl-cluster-demo-qtcompositor.bb
new file mode 100644 (file)
index 0000000..d6f3256
--- /dev/null
+++ b/recipes-platform/images/agl-cluster-demo-qtcompositor.bb
@@ -0,0 +1,15 @@
+DESCRIPTION = "AGL Cluster Demo Qtwayland Compositor image currently contains a \
+simple cluster interface and some AGL service."
+
+require agl-cluster-demo-qtcompositor.inc
+
+LICENSE = "MIT"
+
+IMAGE_FEATURES_append = " \
+    "
+
+# add packages for cluster demo qtcompositor
+IMAGE_INSTALL_append = " \
+    packagegroup-agl-cluster-demo-qtcompositor \
+    "
+

diff --git a/recipes-platform/images/agl-cluster-demo-qtcompositor.inc b/recipes-platform/images/agl-cluster-demo-qtcompositor.inc
new file mode 100644 (file)
index 0000000..11c1ebc
--- /dev/null
+++ b/recipes-platform/images/agl-cluster-demo-qtcompositor.inc
@@ -0,0 +1,2 @@
+# Base image
+require recipes-platform/images/agl-image-cluster-qt5.inc

diff --git a/recipes-platform/packagegroups/packagegroup-agl-cluster-demo-qtcompositor.bb b/recipes-platform/packagegroups/packagegroup-agl-cluster-demo-qtcompositor.bb
new file mode 100644 (file)
index 0000000..879248c
--- /dev/null
+++ b/recipes-platform/packagegroups/packagegroup-agl-cluster-demo-qtcompositor.bb
@@ -0,0 +1,60 @@
+SUMMARY = "The software for AGL Cluster Demo Qtwayland Compositor"
+DESCRIPTION = "A set of packages belong to AGL Cluster Demo Qtwayland Compositor"
+
+LICENSE = "MIT"
+
+inherit packagegroup
+
+PACKAGES = "\
+    packagegroup-agl-cluster-demo-qtcompositor \
+    "
+
+ALLOW_EMPTY_${PN} = "1"
+
+RDEPENDS_${PN} += "\
+    packagegroup-agl-profile-cluster-qtcompositor \
+    "
+
+AGL_SERVICE = " \
+    agl-service-bluetooth \
+    agl-service-can-low-level \
+    agl-service-data-persistence \
+    agl-service-gps \
+    agl-service-network \
+    agl-service-unicens \
+    agl-service-hvac \
+    agl-service-nfc \
+    agl-service-identity-agent \
+    "
+
+SMARTDEVICELINK = "${@bb.utils.contains('DISTRO_FEATURES', 'agl-sdl', \
+    'sdl-core', '', d)}"
+
+# fonts
+TTF_FONTS = " \
+    ttf-bitstream-vera \
+    ttf-dejavu-sans \
+    ttf-dejavu-sans-mono \
+    ttf-dejavu-serif \
+    "
+
+AGL_APPS = " \
+    cluster-gauges-qtcompositor \
+    "
+
+RDEPENDS_${PN}_append = " \
+    libva-utils \
+    linux-firmware-ralink \
+    connman \
+    connman-client \
+    connman-tools \
+    cluster-connman-conf \
+    iproute2 \
+    dhcp-client \
+    can-utils \
+    most \
+    ${TTF_FONTS} \
+    ${AGL_SERVICE} \
+    ${AGL_APPS} \
+    ${SMARTDEVICELINK} \
+"