meta-agl-profile-graphical*: Add qtaglextras and dependencies

Add qtaglextras to meta-agl-profile-graphical-qt5, and its
dependencies libhomescreen and agl-service-homescreen to
meta-agl-profile-graphical.  This is required to fix building the
cluster demo SDK now that qtaglextras has been added to
packagegroup-qt5-toolchain-target.  These changes are a partial
backport of the move of the contents of meta-hmi-framework in
master / Halibut.

Bug-AGL: SPEC-2484

Change-Id: I94493c65d2253ceb2204b34a8ad216910851a54b
Signed-off-by: Scott Murray <scott.murray@konsulko.com>

diff --git a/meta-agl-profile-graphical-qt5/recipes-qt/qtaglextras/qtaglextras_git.bb b/meta-agl-profile-graphical-qt5/recipes-qt/qtaglextras/qtaglextras_git.bb
new file mode 100644 (file)
index 0000000..a874a9c
--- /dev/null
+++ b/meta-agl-profile-graphical-qt5/recipes-qt/qtaglextras/qtaglextras_git.bb
@@ -0,0 +1,28 @@
+LICENSE     = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE-2.0.txt;md5=3b83ef96387f14655fc854ddc3c6bd57"
+
+DEPENDS += "qtbase qtdeclarative qtquickcontrols2 qlibwindowmanager libhomescreen"
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/qtaglextras;protocol=https;branch=${AGL_BRANCH}"
+SRCREV = "2fe96de41a540477d425403cf3a59ec6f5871521"
+
+PV = "5.8.0+git${SRCPV}"
+S = "${WORKDIR}/git/"
+
+inherit qmake5
+
+PACKAGES += "${PN}-mkspecs"
+
+FILES_${PN}-mkspecs = "\
+    ${OE_QMAKE_PATH_QT_ARCHDATA}/mkspecs \
+"
+
+FILES_${PN}-dev += " \
+    ${OE_QMAKE_PATH_LIBS}/lib*${SOLIBSDEV} \
+    ${OE_QMAKE_PATH_LIBS}/pkgconfig \
+    ${OE_QMAKE_PATH_LIBS}/cmake/* \
+    ${OE_QMAKE_PATH_LIBS}/*.prl \
+    ${OE_QMAKE_PATH_LIBS}/*.la \
+    ${OE_QMAKE_PATH_DATA}/* \
+    ${OE_QMAKE_PATH_HEADERS}/* \
+"

diff --git a/meta-agl-profile-graphical/recipes-apis/agl-service-homescreen/agl-service-homescreen_git.bb b/meta-agl-profile-graphical/recipes-apis/agl-service-homescreen/agl-service-homescreen_git.bb
new file mode 100644 (file)
index 0000000..b56f47c
--- /dev/null
+++ b/meta-agl-profile-graphical/recipes-apis/agl-service-homescreen/agl-service-homescreen_git.bb
@@ -0,0 +1,14 @@
+SUMMARY     = "Homescreen binding and client library for application"
+DESCRIPTION = "agl-service-homescreen is the binding library"
+HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/apps/agl-service-homescreen"
+SECTION     = "HMI"
+LICENSE     = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
+
+DEPENDS = "dbus glib-2.0 af-binder json-c"
+
+inherit cmake aglwgt
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/agl-service-homescreen;protocol=https;branch=${AGL_BRANCH}"
+SRCREV = "b730d31a7e5e23756ab1b076de21d41369a500c5"
+S = "${WORKDIR}/git"

diff --git a/meta-agl-profile-graphical/recipes-graphics/libhomescreen/libhomescreen/org.agl.statusbar.conf b/meta-agl-profile-graphical/recipes-graphics/libhomescreen/libhomescreen/org.agl.statusbar.conf
new file mode 100644 (file)
index 0000000..dc3852e
--- /dev/null
+++ b/meta-agl-profile-graphical/recipes-graphics/libhomescreen/libhomescreen/org.agl.statusbar.conf
@@ -0,0 +1,16 @@
+<!DOCTYPE busconfig PUBLIC
+"-//freedesktop//DTD D-BUS Bus Configuration 1.0//EN"
+"http://www.freedesktop.org/standards/dbus/1.0/busconfig.dtd">
+<busconfig>
+       <policy context="default">
+               <!-- Allow everyone to talk to main service. We'll later add an agent to
+                    only share the location if user allows it. -->
+               <allow send_interface="org.agl.statusbar"/>
+       </policy>
+
+       <policy user="root">
+               <!-- Allow root to own the name on the bus -->
+               <allow own="org.agl.statusbar"/>
+       </policy>
+</busconfig>
+

diff --git a/meta-agl-profile-graphical/recipes-graphics/libhomescreen/libhomescreen_git.bb b/meta-agl-profile-graphical/recipes-graphics/libhomescreen/libhomescreen_git.bb
new file mode 100644 (file)
index 0000000..1c9a38c
--- /dev/null
+++ b/meta-agl-profile-graphical/recipes-graphics/libhomescreen/libhomescreen_git.bb
@@ -0,0 +1,26 @@
+SUMMARY     = "AGL Home Screen Library"
+DESCRIPTION = "libhomescreen"
+HOMEPAGE    = "http://docs.automotivelinux.org"
+LICENSE     = "Apache-2.0"
+SECTION     = "libs"
+
+BBCLASSEXTEND = " nativesdk"
+
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
+
+DEPENDS = "af-binder json-c"
+
+inherit cmake
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/p/src/libhomescreen.git;protocol=https;branch=${AGL_BRANCH} \
+          file://org.agl.statusbar.conf \
+         "
+SRCREV = "d01f3c61041ff7b8d2d942f99680407ee10320bc"
+S = "${WORKDIR}/git"
+
+do_install_append() {
+       mkdir -p ${D}${sysconfdir}/dbus-1/session.d
+       install -m 0644 ${WORKDIR}/org.agl.statusbar.conf  ${D}${sysconfdir}/dbus-1/session.d
+}
+
+RDEPENDS_${PN} = "agl-service-homescreen"