X-Git-Url: https://gerrit.automotivelinux.org/gerrit/gitweb?a=blobdiff_plain;f=recipes-platform%2Fimages%2Fagl-kvm-demo-platform.bb;h=ddb2ddb459ea75c435d146eb3d691204969045c2;hb=refs%2Fheads%2Fnext;hp=338b3e6c5fea90b869e3512cb1062f5146c25531;hpb=0c14b48d5b0c1129e79f7a59daaedd3f55989c5c;p=AGL%2Fmeta-agl-demo.git

diff --git a/recipes-platform/images/agl-kvm-demo-platform.bb b/recipes-platform/images/agl-kvm-demo-platform.bb
deleted file mode 100644
index 338b3e6c5..000000000
--- a/recipes-platform/images/agl-kvm-demo-platform.bb
+++ /dev/null
@@ -1,72 +0,0 @@
-DESCRIPTION = "AGL KVM+QEMU Demo Platform image."
-
-LICENSE = "MIT"
-
-require recipes-platform/images/agl-image-compositor.bb
-require agl-demo-features.inc
-
-IMAGE_FEATURES += "splash package-management ssh-server-openssh"
-
-# If building with "agl-kvm-host-kuksa", the databroker and likely
-# some clients run on the host
-IMAGE_FEATURES += " \
-    ${@bb.utils.contains("AGL_FEATURES", "agl-kvm-host-kuksa", "kuksa-val-databroker kuksa-val-databroker-client", "", d)} \
-"
-
-# Add packages for KVM+QEMU demo platform here
-IMAGE_INSTALL += " \
-    packagegroup-agl-core-connectivity \
-    kernel-image \
-    agl-compositor \
-    weston-ini-conf-kvm \
-    output-udev-conf \
-    native-shell-client \
-    qemu \
-    ${QEMU_GUEST_CONFIGS} \
-    util-linux-taskset \
-    screen \
-    simple-can-simulator \
-    alsa-utils \
-"
-
-# Potential size reduction options
-#IMAGE_LINGUAS = " "
-#NO_RECOMMENDATIONS = "1"
-
-GUEST_MACHINE ?= "virtio-${TUNE_ARCH}"
-
-GUEST_VM1_IMAGE ?= "agl-ivi-demo-platform-flutter"
-GUEST_VM2_IMAGE ?= "agl-cluster-demo-platform-flutter"
-
-GUEST_IMAGES ?= "agl-kvm-guest:${GUEST_VM1_IMAGE} agl-kvm-guest:${GUEST_VM2_IMAGE}"
-
-QEMU_GUEST_CONFIGS ?= ""
-
-python __anonymous() {
-    for c in (d.getVar('GUEST_IMAGES') or "").split():
-        (mc, image) = c.split(':')
-        dependency = 'mc::' + mc + ':' + image + ':do_image_complete'
-        d.appendVarFlag('do_rootfs', 'mcdepends', ' ' + dependency)
-
-        # Assume there is a qemu-config-X package for guest image X
-        d.appendVar('QEMU_GUEST_CONFIGS', ' ' + 'qemu-config-' + image)
-}
-
-install_guest_images() {
-    for c in ${GUEST_IMAGES}; do
-        config=${c%:*}
-        image=${c#*:}
-        name=${image}
-        rm -rf  ${IMAGE_ROOTFS}/var/lib/machines/${name}
-        install -m 0755 -d ${IMAGE_ROOTFS}/var/lib/machines/${name}
-        src="${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/${image}-${GUEST_MACHINE}.ext4"
-        bbnote "Installing ${src}"
-        install -m 0600 ${src} ${IMAGE_ROOTFS}/var/lib/machines/${name}/
-	# Placeholder until booting from kernel in VM image is worked out
-        install -m 0600 ${TOPDIR}/tmp-${config}/deploy/images/${GUEST_MACHINE}/Image-${GUEST_MACHINE}.bin ${IMAGE_ROOTFS}/var/lib/machines/${name}/
-    done
-}
-
-ROOTFS_POSTPROCESS_COMMAND += "install_guest_images; "
-
-IMAGE_ROOTFS_EXTRA_SPACE:append = "${@bb.utils.contains("DISTRO_FEATURES", "systemd", " + 4096", "" ,d)}"