X-Git-Url: https://gerrit.automotivelinux.org/gerrit/gitweb?a=blobdiff_plain;f=recipes-demo%2Fnavigation%2Ftbtnavi_git.bb;h=3c6571b15603914d63acb99b956d6535b9d60900;hb=b26515dcf2afc510cc59782f99965f10b96be433;hp=5981cc58490a8c61150845bb77d59b85549b68fa;hpb=6cce1d8fcff72bd429a6f0aea23fc5666fd67878;p=AGL%2Fmeta-agl-demo.git

diff --git a/recipes-demo/navigation/tbtnavi_git.bb b/recipes-demo/navigation/tbtnavi_git.bb
index 5981cc584..3c6571b15 100644
--- a/recipes-demo/navigation/tbtnavi_git.bb
+++ b/recipes-demo/navigation/tbtnavi_git.bb
@@ -16,21 +16,87 @@ DEPENDS = " \
     qtquickcontrols2 \
     qtlocation \
     libqtappfw \
-    wayland-native \
     qtwayland-native \
+    protobuf \
+    grpc \
+    grpc-native \
 "
 
 PV = "2.0+git${SRCPV}"
 
-SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/tbtnavi;protocol=https;branch=${AGL_BRANCH}"
-SRCREV = "${AGL_APP_REVISION}"
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/tbtnavi;protocol=https;branch=${AGL_BRANCH} \
+           file://tbtnavi.service \
+           file://tbtnavi.conf \
+           file://tbtnavi.conf.kvm-demo \
+           file://tbtnavi.conf.gateway-demo \
+           file://tbtnavi.token \
+           file://kvm.conf \
+"
+SRCREV = "f00c1e19f5c4cbcd185c8043f3062612bf1537f7"
 
 S = "${WORKDIR}/git"
 
-inherit qmake5 pkgconfig
+inherit meson systemd pkgconfig update-alternatives
+
+SYSTEMD_SERVICE:${PN} = "${BPN}.service"
+
+do_install:append() {
+    install -D -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
+
+    install -D -m 0644 ${WORKDIR}/kvm.conf ${D}${systemd_system_unitdir}/${BPN}.service.d/kvm.conf
+
+    # Currently using default global client and CA certificates
+    # for KUKSA.val SSL, installing app specific ones would go here.
+
+    # VIS authorization token file for KUKSA.val should ideally not
+    # be readable by other users, but currently that's not doable
+    # until a packaging/sandboxing/MAC scheme is (re)implemented or
+    # something like OAuth is plumbed in as an alternative.
+    install -d ${D}${sysconfdir}/xdg/AGL/tbtnavi
+    install -m 0644 ${WORKDIR}/tbtnavi.conf ${D}${sysconfdir}/xdg/AGL/tbtnavi.conf.default
+    install -m 0644 ${WORKDIR}/tbtnavi.conf.kvm-demo ${D}${sysconfdir}/xdg/AGL/
+    install -m 0644 ${WORKDIR}/tbtnavi.conf.gateway-demo ${D}${sysconfdir}/xdg/AGL/
+    install -m 0644 ${WORKDIR}/tbtnavi.token ${D}${sysconfdir}/xdg/AGL/tbtnavi/
+}
+
+ALTERNATIVE_LINK_NAME[tbtnavi.conf] = "${sysconfdir}/xdg/AGL/tbtnavi.conf"
 
 RDEPENDS:${PN} += " \
+    qtwayland \
+    qtbase-qmlplugins \
+    qtgraphicaleffects-qmlplugins \
     qtlocation \
     ondemandnavi-config \
     libqtappfw \
 "
+
+PACKAGE_BEFORE_PN += "${PN}-conf ${PN}-conf-kvm ${PN}-conf-kvm-demo ${PN}-conf-gateway-demo"
+
+FILES:${PN}-conf += "${sysconfdir}/xdg/AGL/tbtnavi.conf.default"
+RDEPENDS:${PN}-conf = "${PN}"
+RPROVIDES:${PN}-conf = "tbtnavi.conf"
+ALTERNATIVE:${PN}-conf = "tbtnavi.conf"
+ALTERNATIVE_TARGET_${PN}-conf = "${sysconfdir}/xdg/AGL/tbtnavi.conf.default"
+
+FILES:${PN}-conf-gateway-demo += " \
+    ${sysconfdir}/xdg/AGL/tbtnavi.conf.gateway-demo \
+"
+RDEPENDS:${PN}-conf-gateway-demo = "${PN}"
+RPROVIDES:${PN}-conf-gateway-demo = "tbtnavi.conf"
+ALTERNATIVE:${PN}-conf-gateway-demo = "tbtnavi.conf"
+ALTERNATIVE_TARGET_${PN}-conf-gateway-demo = "${sysconfdir}/xdg/AGL/tbtnavi.conf.gateway-demo"
+ALTERNATIVE_PRIORITY_${PN}-conf-gateway-demo = "20"
+
+FILES:${PN}-conf-kvm += " \
+    ${systemd_system_unitdir}/tbtnavi.service.d/kvm.conf \
+"
+RDEPENDS:${PN}-conf-kvm = "${PN}"
+
+FILES:${PN}-conf-kvm-demo += " \
+    ${sysconfdir}/xdg/AGL/tbtnavi.conf.kvm-demo \
+"
+RDEPENDS:${PN}-conf-kvm-demo = "${PN} ${PN}-conf-kvm"
+RPROVIDES:${PN}-conf-kvm-demo = "tbtnavi.conf"
+ALTERNATIVE:${PN}-conf-kvm-demo = "tbtnavi.conf"
+ALTERNATIVE_TARGET_${PN}-conf-kvm-demo = "${sysconfdir}/xdg/AGL/tbtnavi.conf.kvm-demo"
+ALTERNATIVE_PRIORITY_${PN}-conf-kvm-demo = "30"