X-Git-Url: https://gerrit.automotivelinux.org/gerrit/gitweb?a=blobdiff_plain;f=recipes-connectivity%2Fagl-vss-proxy%2Fagl-vss-proxy_git.bb;fp=recipes-connectivity%2Fagl-vss-proxy%2Fagl-vss-proxy_git.bb;h=b16116e652a0b6f8cb487c4431c851e4fec1b62f;hb=b26515dcf2afc510cc59782f99965f10b96be433;hp=0000000000000000000000000000000000000000;hpb=2e0fd28b2470f6d81bfb1b0b273af5742060ed6a;p=AGL%2Fmeta-agl-demo.git

diff --git a/recipes-connectivity/agl-vss-proxy/agl-vss-proxy_git.bb b/recipes-connectivity/agl-vss-proxy/agl-vss-proxy_git.bb
new file mode 100644
index 000000000..b16116e65
--- /dev/null
+++ b/recipes-connectivity/agl-vss-proxy/agl-vss-proxy_git.bb
@@ -0,0 +1,47 @@
+SUMMARY     = "AGL VSS Proxy"
+DESCRIPTION = "AGL VSS Proxy"
+HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/agl-vss-proxy"
+
+LICENSE     = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
+
+DEPENDS = " \
+    glib-2.0 \
+    yaml-cpp \
+    protobuf-native \
+    grpc-native \
+    protobuf \
+    grpc \
+    kuksa-databroker \
+    mosquitto \
+"
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/agl-vss-proxy;protocol=https;branch=${AGL_BRANCH} \
+           file://agl-vss-proxy.token \
+"
+SRCREV  = "e437300d0b5c20114ea1843dbf00815304af3f27"
+
+PV = "1.0+git${SRCPV}"
+S  = "${WORKDIR}/git"
+
+inherit meson pkgconfig systemd
+
+EXTRA_OEMESON += "-Dprotos=${STAGING_INCDIR}"
+
+SYSTEMD_SERVICE:${PN} = "agl-vss-proxy.service"
+
+do_install:append() {
+    # Currently using default global client and CA certificates
+    # for KUKSA.val SSL, installing app specific ones would go here.
+
+    # VIS authorization token file for KUKSA.val should ideally not
+    # be readable by other users, but currently that's not doable
+    # until a packaging/sandboxing/MAC scheme is (re)implemented or
+    # something like OAuth is plumbed in as an alternative.
+    install -d ${D}${sysconfdir}/agl-vss-proxy
+    install -m 0644 ${WORKDIR}/agl-vss-proxy.token ${D}${sysconfdir}/agl-vss-proxy/
+}
+
+FILES:${PN} += "${systemd_system_unitdir}"
+
+RDEPENDS:${PN} += "kuksa-databroker kuksa-databroker-agl"