X-Git-Url: https://gerrit.automotivelinux.org/gerrit/gitweb?a=blobdiff_plain;f=libs%2Fnanopb%2Ftests%2Falltypes_proto3%2FSConscript;fp=libs%2Fnanopb%2Ftests%2Falltypes_proto3%2FSConscript;h=c0b2fc1b9e1ca64b40fc5e40ca002e04fd4600c8;hb=32e25cbca210a359b09768537b6f443fe90a3070;hp=0000000000000000000000000000000000000000;hpb=76c43dec62b2e21cd6446360c00d4fe6b437533f;p=apps%2Fagl-service-can-low-level.git

diff --git a/libs/nanopb/tests/alltypes_proto3/SConscript b/libs/nanopb/tests/alltypes_proto3/SConscript
new file mode 100644
index 00000000..c0b2fc1b
--- /dev/null
+++ b/libs/nanopb/tests/alltypes_proto3/SConscript
@@ -0,0 +1,45 @@
+# Version of AllTypes test case for protobuf 3 file format.
+
+Import("env")
+
+import re
+match = None
+if 'PROTOC_VERSION' in env:
+    match = re.search('([0-9]+).([0-9]+).([0-9]+)', env['PROTOC_VERSION'])
+
+if match:
+    version = map(int, match.groups())
+
+# proto3 syntax is supported by protoc >= 3.0.0
+if env.GetOption('clean') or (match and version[0] >= 3):
+
+    env.NanopbProto(["alltypes", "alltypes.options"])
+    enc = env.Program(["encode_alltypes.c", "alltypes.pb.c", "$COMMON/pb_encode.o", "$COMMON/pb_common.o"])
+    dec = env.Program(["decode_alltypes.c", "alltypes.pb.c", "$COMMON/pb_decode.o", "$COMMON/pb_common.o"])
+
+    # Test the round-trip from nanopb encoder to nanopb decoder
+    env.RunTest(enc)
+    env.RunTest([dec, "encode_alltypes.output"])
+
+    # Re-encode the data using protoc, and check that the results from nanopb
+    # match byte-per-byte to the protoc output.
+    env.Decode("encode_alltypes.output.decoded",
+               ["encode_alltypes.output", "alltypes.proto"],
+               MESSAGE='AllTypes')
+    env.Encode("encode_alltypes.output.recoded",
+               ["encode_alltypes.output.decoded", "alltypes.proto"],
+               MESSAGE='AllTypes')
+    env.Compare(["encode_alltypes.output", "encode_alltypes.output.recoded"])
+
+    # Do the same checks with the optional fields present.
+    env.RunTest("optionals.output", enc, ARGS = ['1'])
+    env.RunTest("optionals.decout", [dec, "optionals.output"], ARGS = ['1'])
+    env.Decode("optionals.output.decoded",
+               ["optionals.output", "alltypes.proto"],
+               MESSAGE='AllTypes')
+    env.Encode("optionals.output.recoded",
+               ["optionals.output.decoded", "alltypes.proto"],
+               MESSAGE='AllTypes')
+    env.Compare(["optionals.output", "optionals.output.recoded"])
+
+