Move the declarations of _pb_ostream_t and _pb_istream_t before first use.

[apps/agl-service-can-low-level.git] / tests / SConstruct

diff --git a/tests/SConstruct b/tests/SConstruct
index 0ec1e54..8bbb31d 100644 (file)
--- a/tests/SConstruct
+++ b/tests/SConstruct
@@ -1,77 +1,56 @@
-env = DefaultEnvironment()
+import os
+env = Environment(ENV = {'PATH': os.environ['PATH']})
 
-env.Append(CPPPATH = ["#../", "#common"])
-
-# Build command for building .pb from .proto using protoc
-def proto_actions(source, target, env, for_signature):
-    dirs = ' '.join(['-I' + env.GetBuildPath(d) for d in env['PROTOCPATH']])
-    return '$PROTOC $PROTOCFLAGS %s -o%s %s' % (dirs, target[0], source[0])
-
-proto_file_builder = Builder(generator = proto_actions,
-                             suffix = '.pb',
-                             src_suffix = '.proto')
-env.Append(BUILDERS = {'Proto': proto_file_builder})
-env.SetDefault(PROTOC = 'protoc')
-
-# Define the include path to find nanopb.proto
-env.Append(PROTOCPATH = ['#../generator', '/usr/include', '.'])
-
-# Build command for running nanopb generator
-import os.path
-def nanopb_targets(target, source, env):
-    basename = os.path.splitext(str(source[0]))[0]
-    target.append(basename + '.pb.h')
-    return target, source
-
-nanopb_file_builder = Builder(action = '$NANOPB_GENERATOR $NANOPB_FLAGS $SOURCE',
-                              suffix = '.pb.c',
-                              src_suffix = '.pb',
-                              emitter = nanopb_targets)
-env.Append(BUILDERS = {'Nanopb': nanopb_file_builder})
-env.SetDefault(NANOPB_GENERATOR = 'python ' + env.GetBuildPath("#../generator/nanopb_generator.py"))
-
-# Combined method to run both protoc and nanopb generator
-def run_protoc_and_nanopb(env, source):
-    b1 = env.Proto(source)
-    b2 = env.Nanopb(source)
-    return b1 + b2
-env.AddMethod(run_protoc_and_nanopb, "NanopbProto")
+# Add the builders defined in site_init.py
+add_nanopb_builders(env)
 
-# Build command that runs a test program and saves the output
-def run_test_actions(source, target, env, for_signature):
-    cmd = str(source[0]) # Name of binary
-    if len(source) > 1:
-        cmd += ' <' + str(source[1]) # Input file
-    cmd += ' >' + str(target[0])
-    return cmd
-
-run_test_builder = Builder(generator = run_test_actions,
-                           suffix = '.output')
-env.Append(BUILDERS = {'RunTest': run_test_builder})
-
-# Build command that decodes a message using protoc
-def decode_actions(source, target, env, for_signature):
-    dirs = ' '.join(['-I' + env.GetBuildPath(d) for d in env['PROTOCPATH']])
-    return '$PROTOC $PROTOCFLAGS %s --decode=%s %s <%s >%s' % (dirs, env['MESSAGE'], source[1], source[0], target[0])
-
-decode_builder = Builder(generator = decode_actions,
-                         suffix = '.decoded')
-env.Append(BUILDERS = {'Decode': decode_builder})    
+# Path to the files shared by tests, and to the nanopb core.
+env.Append(CPPPATH = ["#../", "#common"])
 
-# Build command that asserts that two files be equal
-def compare_files(target, source, env):
-    data1 = open(str(source[0]), 'rb').read()
-    data2 = open(str(source[1]), 'rb').read()
-    if data1 == data2:
-#        open(str(target[0]), 'w').write('OK')
-        return 0
+# Path for finding nanopb.proto
+env.Append(PROTOCPATH = '#../generator')
+
+# Check the compilation environment, unless we are just cleaning up.
+if not env.GetOption('clean'):
+    conf = Configure(env)
+
+    # If the platform doesn't support C99, use our own header file instead.
+    stdbool = conf.CheckCHeader('stdbool.h')
+    stdint = conf.CheckCHeader('stdint.h')
+    stddef = conf.CheckCHeader('stddef.h')
+    string = conf.CheckCHeader('string.h')
+    if not stdbool or not stdint or not stddef or not string:
+        conf.env.Append(CPPDEFINES = {'PB_SYSTEM_HEADER': '\\"pb_syshdr.h\\"'})
+        conf.env.Append(CPPPATH = "#../compat")
+        
+        if stdbool: conf.env.Append(CPPDEFINES = {'HAVE_STDBOOL_H': 1})
+        if stdint: conf.env.Append(CPPDEFINES = {'HAVE_STDINT_H': 1})
+        if stddef: conf.env.Append(CPPDEFINES = {'HAVE_STDDEF_H': 1})
+        if string: conf.env.Append(CPPDEFINES = {'HAVE_STRING_H': 1})
+        
+    # Check if we can use pkg-config to find protobuf include path
+    status, output = conf.TryAction('pkg-config protobuf --variable=includedir > $TARGET')
+    if status:
+        conf.env.Append(PROTOCPATH = output.strip())
     else:
-        return "Test failed: %s and %s differ!" % (source[0], source[1])
-
-compare_builder = Builder(action = compare_files,
-                          suffix = '.equal')
-env.Append(BUILDERS = {'Compare': compare_builder})
-
+        conf.env.Append(PROTOCPATH = '/usr/include')
+        
+    # End the config stuff
+    env = conf.Finish()
+
+# Initialize the CCFLAGS according to the compiler
+if 'cl' in env['CC']:
+    # Microsoft Visual C++
+    
+    # Debug info on, warning level 2 for tests, warnings as errors
+    env.Append(CCFLAGS = '/Zi /W2 /WX')
+    env.Append(LINKFLAGS = '/DEBUG')
+    
+    # PB_RETURN_ERROR triggers C4127 because of while(0)
+    env.Append(CCFLAGS = '/wd4127')
+    
+    
+    
 # Now include the SConscript files from all subdirectories
 SConscript(Glob('*/SConscript'), exports = 'env')