+inherit qmake5 pkgconfig agl-app update-alternatives
+
+AGL_APP_ID = "navigation"
+AGL_APP_NAME = "Navigation"
+
+do_install:append() {
+ # Currently using default global client and CA certificates
+ # for KUKSA.val SSL, installing app specific ones would go here.
+
+ # VIS authorization token file for KUKSA.val should ideally not
+ # be readable by other users, but currently that's not doable
+ # until a packaging/sandboxing/MAC scheme is (re)implemented or
+ # something like OAuth is plumbed in as an alternative.
+ install -d ${D}${sysconfdir}/xdg/AGL/navigation
+ install -m 0644 ${WORKDIR}/navigation.conf ${D}${sysconfdir}/xdg/AGL/navigation.conf.default
+ install -m 0644 ${WORKDIR}/navigation.conf.kvm-demo ${D}${sysconfdir}/xdg/AGL/
+ install -m 0644 ${WORKDIR}/navigation.conf.gateway-demo ${D}${sysconfdir}/xdg/AGL/
+ install -m 0644 ${WORKDIR}/navigation.token ${D}${sysconfdir}/xdg/AGL/navigation/
+}
+
+ALTERNATIVE_LINK_NAME[navigation.conf] = "${sysconfdir}/xdg/AGL/navigation.conf"
+
+PACKAGE_BEFORE_PN += "${PN}-conf ${PN}-conf-kvm-demo ${PN}-conf-gateway-demo"
+
+FILES:${PN}-conf += "${sysconfdir}/xdg/AGL/navigation.conf.default"
+RDEPENDS:${PN}-conf = "${PN}"
+RPROVIDES:${PN}-conf = "navigation.conf"
+ALTERNATIVE:${PN}-conf = "navigation.conf"
+ALTERNATIVE_TARGET_${PN}-conf = "${sysconfdir}/xdg/AGL/navigation.conf.default"
+
+FILES:${PN}-conf-gateway-demo += "${sysconfdir}/xdg/AGL/navigation.conf.gateway-demo"
+RDEPENDS:${PN}-conf-gateway-demo = "${PN}"
+RPROVIDES:${PN}-conf-gateway-demo = "navigation.conf"
+ALTERNATIVE:${PN}-conf-gateway-demo = "navigation.conf"
+ALTERNATIVE_TARGET_${PN}-conf-gateway-demo = "${sysconfdir}/xdg/AGL/navigation.conf.gateway-demo"
+ALTERNATIVE_PRIORITY_${PN}-conf-gateway-demo = "20"