tests/SConstruct

   1 Help('''
   2 Type 'scons' to build and run all the available test cases.
   3 It will automatically detect your platform and C compiler and
   4 build appropriately.
   5
   6 You can modify the behavious using following options:
   7 CC          Name of C compiler
   8 CXX         Name of C++ compiler
   9 CCFLAGS     Flags to pass to the C compiler
  10 CXXFLAGS    Flags to pass to the C++ compiler
  11
  12 For example, for a clang build, use:
  13 scons CC=clang CXX=clang++
  14 ''')
  15
  16 import os
  17 env = Environment(ENV = os.environ, tools = ['default', 'nanopb'])
  18
  19 # Allow overriding the compiler with scons CC=???
  20 if 'CC' in ARGUMENTS: env.Replace(CC = ARGUMENTS['CC'])
  21 if 'CXX' in ARGUMENTS: env.Replace(CXX = ARGUMENTS['CXX'])
  22 if 'CFLAGS' in ARGUMENTS: env.Append(CCFLAGS = ARGUMENTS['CFLAGS'])
  23 if 'CXXFLAGS' in ARGUMENTS: env.Append(CCFLAGS = ARGUMENTS['CXXFLAGS'])
  24
  25 # Add the builders defined in site_init.py
  26 add_nanopb_builders(env)
  27
  28 # Path to the files shared by tests, and to the nanopb core.
  29 env.Append(CPPPATH = ["#../", "$COMMON"])
  30
  31 # Path for finding nanopb.proto
  32 env.Append(PROTOCPATH = '#../generator')
  33
  34 # Check the compilation environment, unless we are just cleaning up.
  35 if not env.GetOption('clean'):
  36     def check_ccflags(context, flags):
  37         '''Check if given CCFLAGS are supported'''
  38         context.Message('Checking support for CCFLAGS="%s"... ' % flags)
  39         oldflags = context.env['CCFLAGS']
  40         context.env.Append(CCFLAGS = flags)
  41         result = context.TryCompile("int main() {return 0;}", '.c')
  42         context.env.Replace(CCFLAGS = oldflags)
  43         context.Result(result)
  44         return result
  45
  46     conf = Configure(env, custom_tests = {'CheckCCFLAGS': check_ccflags})
  47
  48     # If the platform doesn't support C99, use our own header file instead.
  49     stdbool = conf.CheckCHeader('stdbool.h')
  50     stdint = conf.CheckCHeader('stdint.h')
  51     stddef = conf.CheckCHeader('stddef.h')
  52     string = conf.CheckCHeader('string.h')
  53     if not stdbool or not stdint or not stddef or not string:
  54         conf.env.Append(CPPDEFINES = {'PB_SYSTEM_HEADER': '\\"pb_syshdr.h\\"'})
  55         conf.env.Append(CPPPATH = "#../extra")
  56
  57         if stdbool: conf.env.Append(CPPDEFINES = {'HAVE_STDBOOL_H': 1})
  58         if stdint: conf.env.Append(CPPDEFINES = {'HAVE_STDINT_H': 1})
  59         if stddef: conf.env.Append(CPPDEFINES = {'HAVE_STDDEF_H': 1})
  60         if string: conf.env.Append(CPPDEFINES = {'HAVE_STRING_H': 1})
  61
  62     # Check if we have mallinfo for memory leak tests
  63     mallinfo = conf.CheckFunc('mallinfo', '#include <malloc.h>\n')
  64     if mallinfo:
  65         conf.env.Append(CPPDEFINES = {'HAVE_MALLINFO': 1})
  66
  67     # Check if we can use pkg-config to find protobuf include path
  68     status, output = conf.TryAction('pkg-config protobuf --variable=includedir > $TARGET')
  69     if status:
  70         conf.env.Append(PROTOCPATH = output.strip())
  71     else:
  72         conf.env.Append(PROTOCPATH = '/usr/include')
  73
  74     # Check if libmudflap is available (only with GCC)
  75     if 'gcc' in env['CC']:
  76         if conf.CheckLib('mudflap'):
  77             conf.env.Append(CCFLAGS = '-fmudflap')
  78             conf.env.Append(LINKFLAGS = '-fmudflap')
  79
  80     # Check if we can use extra strict warning flags (only with GCC)
  81     extra = '-Wcast-qual -Wlogical-op -Wconversion'
  82     extra += ' -fstrict-aliasing -Wstrict-aliasing=1'
  83     extra += ' -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls'
  84     extra += ' -Wstack-protector '
  85     if 'gcc' in env['CC']:
  86         if conf.CheckCCFLAGS(extra):
  87             conf.env.Append(CORECFLAGS = extra)
  88
  89     # End the config stuff
  90     env = conf.Finish()
  91
  92 # Initialize the CCFLAGS according to the compiler
  93 if 'gcc' in env['CC']:
  94     # GNU Compiler Collection
  95
  96     # Debug info, warnings as errors
  97     env.Append(CFLAGS = '-ansi -pedantic -g -O0 -Wall -Werror --coverage -fstack-protector-all')
  98     env.Append(CORECFLAGS = '-Wextra')
  99     env.Append(LINKFLAGS = '--coverage')
 100
 101     # We currently need uint64_t anyway, even though ANSI C90 otherwise..
 102     env.Append(CFLAGS = '-Wno-long-long')
 103 elif 'clang' in env['CC']:
 104     # CLang
 105     env.Append(CFLAGS = '-ansi -g -O0 -Wall -Werror')
 106     env.Append(CORECFLAGS = ' -Wextra -Wcast-qual -Wconversion')
 107 elif 'cl' in env['CC']:
 108     # Microsoft Visual C++
 109
 110     # Debug info on, warning level 2 for tests, warnings as errors
 111     env.Append(CFLAGS = '/Zi /W2 /WX')
 112     env.Append(LINKFLAGS = '/DEBUG')
 113
 114     # More strict checks on the nanopb core
 115     env.Append(CORECFLAGS = '/W4')
 116
 117     # PB_RETURN_ERROR triggers C4127 because of while(0)
 118     env.Append(CFLAGS = '/wd4127')
 119 elif 'tcc' in env['CC']:
 120     # Tiny C Compiler
 121     env.Append(CFLAGS = '-Wall -Werror -g')
 122
 123 env.SetDefault(CORECFLAGS = '')
 124
 125 if 'clang++' in env['CXX']:
 126     env.Append(CXXFLAGS = '-g -O0 -Wall -Werror -Wextra -Wno-missing-field-initializers')
 127 elif 'g++' in env['CXX']:
 128     env.Append(CXXFLAGS = '-g -O0 -Wall -Werror -Wextra -Wno-missing-field-initializers')
 129 elif 'cl' in env['CXX']:
 130     env.Append(CXXFLAGS = '/Zi /W2 /WX')
 131
 132 # Now include the SConscript files from all subdirectories
 133 import os.path
 134 env['VARIANT_DIR'] = 'build'
 135 env['BUILD'] = '#' + env['VARIANT_DIR']
 136 env['COMMON'] = '#' + env['VARIANT_DIR'] + '/common'
 137 for subdir in Glob('*/SConscript'):
 138     SConscript(subdir, exports = 'env', variant_dir = env['VARIANT_DIR'] + '/' + os.path.dirname(str(subdir)))
 139