tests/SConstruct

   1 Help('''
   2 Type 'scons' to build and run all the available test cases.
   3 It will automatically detect your platform and C compiler and
   4 build appropriately.
   5
   6 You can modify the behavious using following options:
   7 CC          Name of C compiler
   8 CXX         Name of C++ compiler
   9 CCFLAGS     Flags to pass to the C compiler
  10 CXXFLAGS    Flags to pass to the C++ compiler
  11
  12 For example, for a clang build, use:
  13 scons CC=clang CXX=clang++
  14 ''')
  15
  16 import os
  17 env = Environment(ENV = os.environ, tools = ['default', 'nanopb'])
  18
  19 # Allow overriding the compiler with scons CC=???
  20 if 'CC' in ARGUMENTS: env.Replace(CC = ARGUMENTS['CC'])
  21 if 'CXX' in ARGUMENTS: env.Replace(CXX = ARGUMENTS['CXX'])
  22 if 'CFLAGS' in ARGUMENTS: env.Append(CCFLAGS = ARGUMENTS['CFLAGS'])
  23 if 'CXXFLAGS' in ARGUMENTS: env.Append(CCFLAGS = ARGUMENTS['CXXFLAGS'])
  24
  25 # Add the builders defined in site_init.py
  26 add_nanopb_builders(env)
  27
  28 # Path to the files shared by tests, and to the nanopb core.
  29 env.Append(CPPPATH = ["#../", "$COMMON"])
  30
  31 # Path for finding nanopb.proto
  32 env.Append(PROTOCPATH = '#../generator')
  33
  34 # Check the compilation environment, unless we are just cleaning up.
  35 if not env.GetOption('clean'):
  36     def check_ccflags(context, flags):
  37         '''Check if given CCFLAGS are supported'''
  38         context.Message('Checking support for CCFLAGS="%s"...' % flags)
  39         oldflags = context.env['CCFLAGS']
  40         context.env.Append(CCFLAGS = flags)
  41         result = context.TryCompile("int main() {return 0;}", '.c')
  42         context.env.Replace(CCFLAGS = oldflags)
  43         context.Result(result)
  44         return result
  45
  46     conf = Configure(env, custom_tests = {'CheckCCFLAGS': check_ccflags})
  47
  48     # If the platform doesn't support C99, use our own header file instead.
  49     stdbool = conf.CheckCHeader('stdbool.h')
  50     stdint = conf.CheckCHeader('stdint.h')
  51     stddef = conf.CheckCHeader('stddef.h')
  52     string = conf.CheckCHeader('string.h')
  53     if not stdbool or not stdint or not stddef or not string:
  54         conf.env.Append(CPPDEFINES = {'PB_SYSTEM_HEADER': '\\"pb_syshdr.h\\"'})
  55         conf.env.Append(CPPPATH = "#../compat")
  56
  57         if stdbool: conf.env.Append(CPPDEFINES = {'HAVE_STDBOOL_H': 1})
  58         if stdint: conf.env.Append(CPPDEFINES = {'HAVE_STDINT_H': 1})
  59         if stddef: conf.env.Append(CPPDEFINES = {'HAVE_STDDEF_H': 1})
  60         if string: conf.env.Append(CPPDEFINES = {'HAVE_STRING_H': 1})
  61
  62     # Check if we can use pkg-config to find protobuf include path
  63     status, output = conf.TryAction('pkg-config protobuf --variable=includedir > $TARGET')
  64     if status:
  65         conf.env.Append(PROTOCPATH = output.strip())
  66     else:
  67         conf.env.Append(PROTOCPATH = '/usr/include')
  68
  69     # Check if libmudflap is available (only with GCC)
  70     if 'gcc' in env['CC']:
  71         if conf.CheckLib('mudflap'):
  72             conf.env.Append(CCFLAGS = '-fmudflap')
  73             conf.env.Append(LINKFLAGS = '-lmudflap -fmudflap')
  74
  75     # Check if we can use extra strict warning flags (only with GCC)
  76     extra = '-Wcast-qual -Wlogical-op -Wconversion'
  77     extra += ' -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls'
  78     extra += ' -Wstack-protector'
  79     if 'gcc' in env['CC']:
  80         if conf.CheckCCFLAGS(extra):
  81             conf.env.Append(CORECFLAGS = extra)
  82
  83     # End the config stuff
  84     env = conf.Finish()
  85
  86 # Initialize the CCFLAGS according to the compiler
  87 if 'gcc' in env['CC']:
  88     # GNU Compiler Collection
  89
  90     # Debug info, warnings as errors
  91     env.Append(CFLAGS = '-ansi -pedantic -g -O0 -Wall -Werror --coverage -fstack-protector-all')
  92     env.Append(CORECFLAGS = '-Wextra')
  93     env.Append(LINKFLAGS = '--coverage')
  94
  95     # We currently need uint64_t anyway, even though ANSI C90 otherwise..
  96     env.Append(CFLAGS = '-Wno-long-long')
  97 elif 'clang' in env['CC']:
  98     # CLang
  99     env.Append(CFLAGS = '-ansi -g -O0 -Wall -Werror')
 100     env.Append(CORECFLAGS = ' -Wextra -Wcast-qual -Wconversion')
 101 elif 'cl' in env['CC']:
 102     # Microsoft Visual C++
 103
 104     # Debug info on, warning level 2 for tests, warnings as errors
 105     env.Append(CFLAGS = '/Zi /W2 /WX')
 106     env.Append(LINKFLAGS = '/DEBUG')
 107
 108     # More strict checks on the nanopb core
 109     env.Append(CORECFLAGS = '/W4')
 110
 111     # PB_RETURN_ERROR triggers C4127 because of while(0)
 112     env.Append(CFLAGS = '/wd4127')
 113 elif 'tcc' in env['CC']:
 114     # Tiny C Compiler
 115     env.Append(CFLAGS = '-Wall -Werror -g')
 116
 117 env.SetDefault(CORECFLAGS = '')
 118
 119 if 'clang++' in env['CXX']:
 120     env.Append(CXXFLAGS = '-g -O0 -Wall -Werror -Wextra -Wno-missing-field-initializers')
 121 elif 'g++' in env['CXX']:
 122     env.Append(CXXFLAGS = '-g -O0 -Wall -Werror -Wextra -Wno-missing-field-initializers')
 123 elif 'cl' in env['CXX']:
 124     env.Append(CXXFLAGS = '/Zi /W2 /WX')
 125
 126 # Now include the SConscript files from all subdirectories
 127 import os.path
 128 env['VARIANT_DIR'] = 'build'
 129 env['BUILD'] = '#' + env['VARIANT_DIR']
 130 env['COMMON'] = '#' + env['VARIANT_DIR'] + '/common'
 131 for subdir in Glob('*/SConscript'):
 132     SConscript(subdir, exports = 'env', variant_dir = env['VARIANT_DIR'] + '/' + os.path.dirname(str(subdir)))
 133